translate-shell-0.9.6.5.ebuild

translate-shell-0.9.6.5.ebuild (text/plain), 888 bytes, created by Ferenc Erki on 2017-12-07 05:51:33 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

DESCRIPTION="Online command-line translator"
HOMEPAGE="https://www.soimort.org/translate-shell/"
SRC_URI="https://github.com/soimort/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+curl +bidi test tts"

RDEPEND="
	app-misc/rlwrap
	>=sys-apps/gawk-4.0.2
	curl? ( net-misc/curl[ssl] )
	bidi? ( dev-libs/fribidi )
	tts? ( || (
		media-sound/mpg123
		app-accessibility/espeak
		media-video/mpv
		media-video/mplayer
		)
	)"
DEPEND="${RDEPEND}
	test? ( app-editors/emacs )
	"

src_test() {
	# actual translation tests need network access,
	# thus won't work inside a portage environment
	sed -i -e "/\$(BUILDDIR)\/\$(COMMAND) -no-init/d" Makefile || die

	emake check
}

src_install() {
	emake PREFIX="${D}/usr" install
}