ebuild that works for me

qbittorrent-4.0.2.ebuild (text/plain), 1.34 KB, created by Klemen Mihevc on 2017-12-04 10:06:43 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit flag-o-matic qmake-utils

DESCRIPTION="BitTorrent client in C++ and Qt"
HOMEPAGE="http://www.qbittorrent.org/"

if [[ ${PV} == *9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/${PN}/qBittorrent.git"
else
	MY_P=${P/_}
	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
	KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
	S=${WORKDIR}/${MY_P}
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="+dbus debug webui +X"
REQUIRED_USE="
	dbus? ( X )
"

RDEPEND="
        >=dev-libs/boost-1.62.0-r1:=
        dev-qt/qtcore:5
        dev-qt/qtnetwork:5[ssl]
        >=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt5,X?]
        dev-qt/qtxml:5
        >=net-libs/libtorrent-rasterbar-1.0.6
        sys-libs/zlib
        dbus? ( dev-qt/qtdbus:5 )
        X? (
                dev-qt/qtgui:5
                dev-qt/qtsvg:5
                dev-qt/qtwidgets:5
        )
"
DEPEND="${RDEPEND}
	dev-qt/linguist-tools:5
	virtual/pkgconfig
"

DOCS=(AUTHORS Changelog CONTRIBUTING.md README.md TODO)

src_configure() {
	econf \
		--with-qtsingleapplication=system \
		$(use_enable dbus qt-dbus) \
		$(use_enable debug) \
		$(use_enable webui) \
		$(use_enable X gui) \
		$(use_enable !X systemd) \

	eqmake5
}

src_install() {
	emake INSTALL_ROOT="${D}" install
	einstalldocs
}