atmelwlandriver-3.4.1.0.ebuild

atmelwlandriver-3.4.1.0.ebuild (text/plain), 1.38 KB, created by Stefan Schweizer (RETIRED) on 2005-01-26 11:13:59 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit linux-mod

DESCRIPTION="ATMEL wireless lan drivers (PCMCIA,PCI,please use at76c503a for USB)"
HOMEPAGE="http://atmelwlandriver.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

IUSE="ncurses pcmcia"
DEPEND="ncurses?  ( >=sys-libs/ncurses-5.2-r2 )"

S=${WORKDIR}/${PN}


pkg_setup() {
	CONFIG_CHECK="NET_RADIO"

	MODULE_NAMES="pcifvnet(net:${S}/objs/pcifvnet/release)"
	if useq pcmcia; then
		CONFIG_CHECK="${CONFIG_CHECK} PCMCIA"
		MODULE_NAMES="${MODULE_NAMES}
	pcmf502r(net:${S}/objs/pcmf502r/release)
	pcmf502r3(net:${S}/objs/pcmf502r3/release)
	pcmf502rd(net:${S}/objs/pcmf502rd/release)
	pcmf502re(net:${S}/objs/pcmf502re/release)
	pcmf504(net:${S}/objs/pcmf504/release)
	pcmf504A_2958(net:${S}/objs/pcmf504A_2958/release)
	pcmf504_2958(net:${S}/objs/pcmf504_2958/release)"
	fi
	linux-mod_pkg_setup
}

src_compile() {
	env -u ARCH make KERNEL_SOURCE=${KV_DIR} buildonly=release pci
	useq pcmcia && env -u ARCH make KERNEL_SOURCE=${KV_DIR} buildonly=release pcmcia
	useq ncurses && make lvnet
}

src_install() {
	linux-mod_src_install
	useq ncurses && dobin src/apps/cmd_line/lvnet
	dodoc README CHANGES
}

pkg_postinst() {
	linux-mod_pkg_postinst
	einfo 'USB Drivers disabled, please use "emerge -va at76c503a" for them'
}