muse-0.9.1.ebuild

muse-0.9.1.ebuild (text/plain), 1.28 KB, created by Lars Wendler (Polynomial-C) (RETIRED) on 2005-01-23 19:40:05 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

IUSE="ncurses gtk debug"

inherit eutils

MY_P=${PN/muse/MuSE}-${PV}
S=${WORKDIR}/${MY_P}

DESCRIPTION="Multiple Streaming Engine, an icecast source streamer"
SRC_URI="ftp://ftp.dyne.org/muse/releases/${MY_P}.tar.gz"
RESTRICT="nomirror"
HOMEPAGE="http://muse.dyne.org/"

KEYWORDS="~ppc ~sparc ~x86"
SLOT="0"
LICENSE="GPL-2"

DEPEND="media-sound/lame
	media-libs/libvorbis
	sys-libs/zlib
	sys-apps/sed
	ncurses? ( sys-libs/ncurses )
	gtk? ( =x11-libs/gtk+-1*
	>=dev-libs/glib-1 )"

src_unpack() {
	unpack ${A}
	cd ${S}
	# adding some fixes (see also http://lists.dyne.org/muse/msg00819.php)
	epatch ${FILESDIR}/${P}-compilefixes.patch
}

src_compile() {
	econf \
	`use_with gtk x` \
	`use_with ncurses rubik` \
	`use_enable debug` || die "econf failed"

	# added -fpermissive to CXXFLAGS as suggested here: http://lists.dyne.org/muse/msg00819.php
	emake CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS} -fpermissive" || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die
	rm -rf ${D}/usr/doc
	dodoc AUTHORS ChangeLog NEWS README TODO KNOWN-BUGS USAGE
}

pkg_postinst() {
	einfo
	einfo "You may want to have a look at /usr/share/doc/${PF}/README.gz for more info."
	einfo
}