nwn-hotu-1.65.ebuild

nwn-hotu-1.65.ebuild (text/plain), 3.02 KB, created by Keri Harris on 2005-01-21 15:31:51 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games eutils

UPDATEVER=${PV//.}
PATCH_URL_BASE=http://content.bioware.com/neverwinternights/linux/${UPDATEVER}/linuxhotuclientupdate1xxto${UPDATEVER}

DESCRIPTION="Neverwinter Nights - Hordes of the Underdark"
HOMEPAGE="http://nwn.bioware.com/downloads/linuxclient.html"
SRC_URI="linguas_fr? (
		http://downloads.bioware.com/neverwinternights/linux/162/nwclienthotuintl.tar.gz
		${PATCH_URL_BASE}fre.tar.gz )
	linguas_de? (
		http://downloads.bioware.com/neverwinternights/linux/162/nwclienthotuintl.tar.gz
		${PATCH_URL_BASE}ger.tar.gz )
	linguas_it? (
		http://downloads.bioware.com/neverwinternights/linux/162/nwclienthotuintl.tar.gz
		${PATCH_URL_BASE}ita.tar.gz )
	linguas_es? (
		http://downloads.bioware.com/neverwinternights/linux/162/nwclienthotuintl.tar.gz
		${PATCH_URL_BASE}spa.tar.gz )
	!linguas_de? ( !linguas_fr? ( !linguas_es? ( !linguas_it? (
		http://nwdownloads.bioware.com/neverwinternights/linux/161/nwclienthotu.tar.gz
		${PATCH_URL_BASE}eng.tar.gz )
	) ) )"

LICENSE="NWN-EULA"
SLOT="0"
KEYWORDS="x86 ~amd64"
IUSE=""
RESTRICT="nostrip nomirror"

RDEPEND="games-rpg/nwn"

S="${WORKDIR}/nwn"

pkg_setup() {
	cdrom_get_cds Data_Shared.zip
	games_pkg_setup
}

src_unpack() {
	mkdir ${S}
	cd ${S}
	local zip
	for zip in Data_Shared Language_data Language_update ; do
		zip=${zip}.zip
		echo ">>> Unpacking ${zip} to ${PWD}"
		unzip -qo "${CDROM_ROOT}"/${zip} || die "failure unpacking ${zip}"
	done
	unpack ${A}	
	
	# Remove unneeded movie files
	rm -fr movies

	# Rename conflicting files
	mv readme.linuxclientupdate.txt readme.linuxhotuclientupdate.txt
	mv readme.txt readme.hotu.txt
}

src_install() {
	dodir ${GAMES_PREFIX_OPT}
	sed \
		-e "s:GENTOO_USER:${GAMES_USER}:" \
		-e "s:GENTOO_GROUP:${GAMES_GROUP}:" \
		-e "s:GENTOO_DIR:${GAMES_PREFIX_OPT}:" \
		${FILESDIR}/${P}-fixinstall > ${S}/fixinstall
	PROBLEM_FILES=""
	if [ -f ${GAMES_PREFIX_OPT}/nwn/patch.key ]; then
		PROBLEM_FILES="patch.key"
	fi
	if [ -f ${GAMES_PREFIX_OPT}/nwn/data/patch.bif ]; then
		PROBLEM_FILES="${PROBLEM_FILES} data/patch.bif"
	fi
	if [ -f ${GAMES_PREFIX_OPT}/nwn/xp1patch.key ]; then
		PROBLEM_FILES="${PROBLEM_FILES} xp1patch.key"
	fi
	if [ -f ${GAMES_PREFIX_OPT}/nwn/data/xp1patch.bif ]; then
		PROBLEM_FILES="${PROBLEM_FILES} data/xp1patch.bif"
	fi
	if [ -f ${GAMES_PREFIX_OPT}/nwn/override/iit_medkit_001.tga ]; then
		PROBLEM_FILES="${PROBLEM_FILES} override/iit_medkit_001.tga"
	fi
	for nw_ch in nw_ch_ac{1,2,3,4,5,6,7,8,9,ani9,b,d,e}.ncs nw_i0_generic.nss ; do
		if [ -f ${GAMES_PREFIX_OPT}/nwn/override/${nw_ch} ]; then
			PROBLEM_FILES="${PROBLEM_FILES} override/${nw_ch}"
		fi
	done
	sed -i \
		-e "/aProblemFiles=()/s:aProblemFiles=():aProblemFiles=(${PROBLEM_FILES}):"	\
		${S}/fixinstall
	mv ${S} ${D}/${GAMES_PREFIX_OPT}
}

pkg_postinst() {
	games_pkg_postinst
	einfo "The NWN HotU linux client is now installed."
	einfo "Proceed with the following step in order to get it working:"
	einfo "Run ${GAMES_PREFIX_OPT}/nwn/fixinstall as root"
}