media-gfx/cura-lulzbot-21.06.ebuild

cura-lulzbot-21.06.ebuild (text/plain), 2.39 KB, created by Richard Ostrow on 2017-07-15 22:29:17 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

PYTHON_COMPAT=( python2_7 )
inherit eutils git-r3 fdo-mime gnome2-utils python-single-r1 multilib

DESCRIPTION="Cura Lulzbot Edition"
HOMEPAGE="https://code.alephobjects.com/diffusion/CURA/"
SRC_URI=""

LICENSE="AGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="${PYTHON_DEPS}
	>=dev-python/pyopengl-3.0.2[${PYTHON_USEDEP}]
	>=dev-python/numpy-1.6.2[${PYTHON_USEDEP}]
	>=dev-python/pyserial-2.6[${PYTHON_USEDEP}]
	dev-python/setuptools
	dev-python/wxpython:3.0[opengl,${PYTHON_USEDEP}]
	net-misc/curl
	|| ( media-gfx/curaengine-lulzbot media-gfx/curaengine )"
DEPEND="${RDEPEND}
	>=dev-python/setuptools-0.6.34[${PYTHON_USEDEP}]
	media-gfx/icoutils
	!media-gfx/cura"

src_unpack() {
	_git-r3_env_setup
	git-r3_fetch https://code.alephobjects.com/diffusion/CURA/cura.git lulzbot-${PV} || die
	git-r3_checkout https://code.alephobjects.com/diffusion/CURA/cura.git
	git-r3_fetch https://code.alephobjects.com/diffusion/CBD/cura-binary-data.git || die
	git-r3_checkout https://code.alephobjects.com/diffusion/CBD/cura-binary-data.git "${WORKDIR}"/${P}/_cura_binary_data
}

src_prepare() {
	cat > cura <<- CURAEOF || die
		#!/bin/sh
		PYTHONPATH="\$PYTHONPATH:${EPREFIX}/usr/share/cura/" "${PYTHON}" "${EPREFIX}"/usr/share/cura/cura.py "\$@"
	CURAEOF
	rm -vf resources/firmware/*.hex || die
	cp -v _cura_binary_data/cura/resources/firmware/* resources/firmware/ || die
	epatch "${FILESDIR}"/cura-21.06-nopower.patch || die
	default
}

src_install() {
	insinto /usr/share/cura
	doins -r Cura resources plugins scripts/linux/cura.py || die
	mkdir tmp
	icotool -x --palette-size=0 -o tmp resources/images/c.png || die
	local array=( 256 128 64 48 32 16 )
	for ((i=0;i<6;i++)) ; do
		newicon --size ${array[i]} tmp/c.png_$((i+1))_${array[i]}x${array[i]}x32.png cura.png || die
	done
	echo ${PV} > "${ED}"usr/share/cura/Cura/version || die
	dobin cura || die

	python_optimize $(find "${ED}" -name '*.py' -exec dirname \{\} + | sort -u)
}

pkg_preinst() {
	gnome2_icon_savelist

	make_desktop_entry cura \
		Cura \
		apps/cura \
		"Graphics;3DGraphics;Engineering;Development"
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}