satyr-0.23.ebuild

satyr-0.23.ebuild (text/plain), 1.15 KB, created by Pacho Ramos on 2017-05-24 11:30:57 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=6
PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )

inherit autotools ltprune python-r1 toolchain-funcs

DESCRIPTION="Satyr is a collection of low-level algorithms for program failure processing"
HOMEPAGE="https://github.com/abrt/satyr"
SRC_URI="https://github.com/abrt/${PN}/archive/${PV}/${P}.tar.gz"

LICENSE="GPL-2+"
SLOT="0"

IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

KEYWORDS="~amd64 ~x86"

RDEPEND="${PYTHON_DEPS}
	>=dev-libs/elfutils-0.158
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
"

src_prepare() {
	default
	./gen-version || die # Needs to be run before full autoreconf
	eautoreconf
	python_copy_sources
}

src_configure() {
	local myconf=(
		--disable-python-manpage
		--with-rpm=no
	)
	
	configure_python() {
		if python_is_python3; then
			econf "${myconf}" --with-python3
		else
			econf "${myconf}" --without-python3
		fi
	}

	python_foreach_impl run_in_build_dir configure_python
}

src_compile() {
	python_foreach_impl run_in_build_dir default
}

src_install() {
	python_foreach_impl run_in_build_dir default
	prune_libtool_files --modules
}