sys-kernel/cryptodev-1.8_pre20170209.ebuild

cryptodev-1.8_pre20170209.ebuild (text/plain), 1.27 KB, created by LABBE Corentin on 2017-03-21 09:39:57 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit linux-info linux-mod

DESCRIPTION="device that allows access to Linux kernel cryptographic drivers"
HOMEPAGE="http://cryptodev-linux.org/index.html"

if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="git://github.com/cryptodev-linux/cryptodev-linux.git"
	S="${WORKDIR}/${PN}-${PV}"
else
	EGIT_COMMIT="6818263667ca488f9b1c86e36ea624c4ea1c309f"
	SRC_URI="https://github.com/cryptodev-linux/cryptodev-linux/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~arm ~x86"
	S="${WORKDIR}/cryptodev-linux-${EGIT_COMMIT}"
fi

LICENSE="GPL-2+"
SLOT="0"
IUSE="examples"

DEPEND="virtual/linux-sources"
RDEPEND=""
#test now compile, but need the module to run
RESTRICT="test"

MODULE_NAMES="cryptodev(extra:${S})"

pkg_pretend() {
	if use kernel_linux ; then
		CONFIG_CHECK="~CRYPTO ~CRYPTO_BLKCIPHER ~CRYPTO_AEAD"
		check_extra_config
	fi
}

pkg_setup() {
	if use kernel_linux ; then
		linux-mod_pkg_setup
	else
		die "cryptodev ebuild only support linux"
	fi
	BUILD_TARGETS="build"
	export KERNEL_DIR
}

src_install() {
	linux-mod_src_install
	if use examples ; then
		docinto examples
		dodoc example/*
	fi
	insinto /usr/include/crypto
	doins crypto/cryptodev.h
}