app-pda/libusbmuxd-9999.ebuild

libusbmuxd-9999.ebuild (text/plain), 1.05 KB, created by Alex on 2017-02-02 12:27:36 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

if [[ ${PV} == "9999" ]]; then
	EGIT_REPO_URI="https://github.com/libimobiledevice/libusbmuxd.git"
	EGIT_BRANCH=master
	inherit autotools git-r3
else            
    KEYWORDS="amd64 ~arm ~ppc ~ppc64 x86"
    SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
fi

DESCRIPTION="USB multiplex daemon for use with Apple iPhone/iPod Touch devices"
HOMEPAGE="http://www.libimobiledevice.org/"

# tools/iproxy.c is GPL-2+, everything else is LGPL-2.1+
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0/2" # based on SONAME of libusbmuxd.so
IUSE="kernel_linux static-libs"

RDEPEND=">=app-pda/libplist-1.11:=
	virtual/libusb:1
	!<app-pda/usbmuxd-1.0.8_p1"
DEPEND="${RDEPEND}
	virtual/os-headers
	virtual/pkgconfig"

DOCS=( AUTHORS README )

src_prepare() {
	[[ ${PV} == "9999" ]] && eautoreconf
}

src_configure() {
	local myeconfargs=( $(use_enable static-libs static) )
	use kernel_linux || myeconfargs+=( --without-inotify )

	econf "${myeconfargs[@]}"
}