ndoutils-2.1.1.ebuild

ndoutils-2.1.1.ebuild (text/plain), 1.44 KB, created by Michael Orlitzky on 2016-11-14 13:58:50 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

DESCRIPTION="Nagios addon to store Nagios data in a MySQL database"
HOMEPAGE="https://github.com/NagiosEnterprises/${PN}"
SRC_URI="${HOMEPAGE}/releases/download/${PV}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

DEPEND="
	dev-perl/DBD-mysql
	dev-perl/DBI
	virtual/mysql"

# The default install targets only install the 4.x module. If we wanted
# to support older versions of Nagios (we don't, they're all insecure),
# then we would need to add 'emake DESTDIR="${D}" install-3x' to
# src_install.
RDEPEND="
	${DEPEND}
	>=net-analyzer/nagios-core-4"

DOCS=(
	'docs/NDOUTILS DB Model.pdf'
	'docs/NDOUtils Documentation.pdf'
	Changelog
	README
	THANKS
	TODO
	UPGRADING
)

PATCHES=(
	"${FILESDIR}"/ndoutils-2.0.0-asprintf.patch
	"${FILESDIR}"/ndoutils-2.0.0-sleep.patch
)

src_configure() {
	econf \
		--sysconfdir=/etc/nagios \
		--enable-mysql
}

src_compile() {
	# The default make target just lists the available make targets.
	emake all
}

src_install() {
	default
	emake DESTDIR="${D}" install-config
	newinitd "${FILESDIR}"/ndo2db.init-nagios3 ndo2db
	dodoc -r docs/html
}

pkg_postinst() {
	einfo "To include NDO in your Nagios setup you'll need to activate"
	einfo "the NDO broker module in ${ROOT}etc/nagios/nagios.cfg:"
	einfo "    broker_module=${ROOT}usr/bin/ndomod-4x.o "\
		"config_file=${ROOT}etc/nagios/ndomod.cfg"
}