ebuild with qt4 and qt5 use flags

vim-qt-20150102-r1.ebuild (text/plain), 3.44 KB, created by torto09 on 2016-04-12 22:45:53 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6
PYTHON_COMPAT=( python{2_7,3_{3,4,5}} )
PYTHON_REQ_USE="threads"

inherit fdo-mime flag-o-matic prefix python-single-r1

DESCRIPTION="Qt GUI version of the Vim text editor"
HOMEPAGE="https://bitbucket.org/equalsraf/vim-qt/wiki/Home"

if [[ ${PV} == *9999* ]]; then
	inherit git-r3
	EGIT_REPO_URI=(
		"https://bitbucket.org/equalsraf/${PN}.git"
		"https://github.com/equalsraf/${PN}.git"
	)
	KEYWORDS=""
else
	SRC_URI="https://github.com/equalsraf/${PN}/archive/package-${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="amd64 x86"
	S="${WORKDIR}/${PN}-package-${PV}"
fi

LICENSE="vim"
SLOT=0
IUSE="acl cscope debug lua luajit lto nls perl python qt4 qt5 racket ruby"

REQUIRED_USE="luajit? ( lua )
	python? ( ${PYTHON_REQUIRED_USE} )
	^^ ( qt4 qt5 )"

RDEPEND="
	app-editors/vim-core[acl?]
	app-eselect/eselect-vi
	sys-libs/ncurses:=
	acl? ( kernel_linux? ( sys-apps/acl ) )
	cscope? ( dev-util/cscope )
	lua? ( luajit? ( dev-lang/luajit:= )
		!luajit? ( dev-lang/lua:=[deprecated] ) )
	nls? ( virtual/libintl )
	perl? ( dev-lang/perl:= )
	python? ( ${PYTHON_DEPS} )
	qt4? ( dev-qt/qtgui:4 )
	qt5? ( dev-qt/qtgui:5 )
	racket? ( dev-scheme/racket )
	ruby? ( dev-lang/ruby:2.0 )"
DEPEND="${RDEPEND}
	dev-util/ctags
	sys-devel/autoconf
	virtual/pkgconfig
	nls? ( sys-devel/gettext )"

pkg_setup() {
	export LC_COLLATE="C" # prevent locale brokenness
	use python && python-single-r1_pkg_setup
}

src_prepare() {
	default

	# Read vimrc from /etc/vim/
	echo '#define SYS_VIMRC_FILE "'${EPREFIX}'/etc/vim/vimrc"' >> \
		"${S}"/src/feature.h
}

src_configure() {
	if use lto ; then
		LDFLAGS_OLD="$LDFLAGS"
		local LDFLAGS="${LDFLAGS} -fno-lto -fno-use-linker-plugin"
	fi

	use debug && append-flags "-DDEBUG"

	local qtver=4
	use qt5 && qtver=5
	local myconf="--enable-multibyte --disable-gpm --with-features=huge
		--enable-gui=qt --with-vim-name=qvim --with-modified-by=Gentoo-${PVR}
		--with-qt-qmake=/usr/lib/qt${qtver}/bin/qmake"
	myconf+=" $(use_enable acl)"
	myconf+=" $(use_enable cscope)"
	myconf+=" $(use_enable nls)"
	myconf+=" $(use_enable lua luainterp)"
	myconf+=" $(use_with luajit)"
	myconf+=" $(use_enable perl perlinterp)"
	myconf+=" $(use_enable racket mzschemeinterp)"
	myconf+=" $(use_enable ruby rubyinterp)"

	if ! use cscope ; then
		sed '/# define FEAT_CSCOPE/d' -i \
			src/feature.h || die 'sed failed'
	fi

	# keep prefix env contained within the EPREFIX
	use prefix && myconf+=" --without-local-dir"

	if use python ; then
		if [[ ${EPYTHON} == python3* ]] ; then
			myconf+=" --enable-python3interp"
			export vi_cv_path_python3="${PYTHON}"
		else
			myconf+=" --enable-pythoninterp"
			export vi_cv_path_python="${PYTHON}"
		fi
	else
		myconf+=" --disable-pythoninterp --disable-python3interp"
	fi

	econf ${myconf}

	if use lto ; then
		LDFLAGS="${LDFLAGS_OLD}"
		sed "s|-fno-lto -fno-use-linker-plugin||g" -i \
			src/auto/config.mk || die 'sed failed'
	fi
}

src_install() {
	dobin src/qvim
	dosym qvim /usr/bin/qvimdiff

	dodir /usr/share/man/man1
	echo ".so vim.1" > "${ED}"/usr/share/man/man1/qvim.1
	echo ".so vimdiff.1" > "${ED}"/usr/share/man/man1/qvimdiff.1

	# track https://bitbucket.org/equalsraf/vim-qt/issue/93/include-desktop-file-in-source
	# for inclusion of desktop file
	newmenu "${FILESDIR}"/vim-qt.desktop vim-qt.desktop
	doicon -s 64 src/qt/icons/vim-qt.png
}

pkg_postinst() {
	fdo-mime_mime_database_update
}

pkg_postrm() {
	fdo-mime_mime_database_update
}