Corrected vips-8.2.2.ebuild

vips-8.2.2.ebuild (text/plain), 2.26 KB, created by * on 2016-03-12 06:20:37 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6
PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
inherit eutils python-single-r1 versionator

DESCRIPTION="VIPS Image Processing Library"
SRC_URI="http://www.vips.ecs.soton.ac.uk/supported/$(get_version_component_range 1-2)/${P}.tar.gz"
HOMEPAGE="http://www.vips.ecs.soton.ac.uk/index.php?title=VIPS"

RESTRICT="mirror"
LICENSE="LGPL-2.1"
SLOT="1"
KEYWORDS="~amd64 ~x86"
IUSE="debug exif fits fftw gsf imagemagick jpeg lcms matio openexr +orc pango
	png python static-libs tiff webp"

RDEPEND=">=dev-libs/glib-2.6:2
	dev-libs/libxml2
	exif? ( >=media-libs/libexif-0.6 )
	fftw? ( sci-libs/fftw:3.0 )
	fits? ( sci-libs/cfitsio )
	gsf? ( >=gnome-extra/libgsf-1.14.27 )
	imagemagick? ( || ( >=media-gfx/imagemagick-5.0.0
		media-gfx/graphicsmagick[imagemagick] ) )
	jpeg? ( virtual/jpeg:0 )
	lcms? ( media-libs/lcms )
	matio? ( >=sci-libs/matio-1.3.4 )
	openexr? ( >=media-libs/openexr-1.2.2 )
	orc? ( >=dev-lang/orc-0.4.11 )
	pango? ( >=x11-libs/pango-1.8 )
	png? ( >=media-libs/libpng-1.2.9:= )
	python? ( ${PYTHON_DEPS}
		>=dev-python/pygobject-3.12.0[$(python_gen_usedep 'python3*')] )
	sys-libs/zlib
	tiff? ( media-libs/tiff:0 )
	webp? ( media-libs/libwebp )"
DEPEND="${RDEPEND}
	dev-util/gtk-doc-am"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

pkg_setup() {
	use python && python-single-r1_pkg_setup
}

src_configure() {
	econf \
		$(use_enable debug) \
		$(use_enable static-libs static) \
		$(use_with exif libexif) \
		$(use_with fftw) \
		$(use_with fits cfitsio) \
		$(use_with gsf) \
		$(use_with imagemagick magick) \
		$(use_with jpeg) \
		$(use_with lcms) \
		$(use_with matio) \
		$(use_with openexr OpenEXR) \
		$(use_with orc) \
		$(use_with pango pangoft2) \
		$(use_with png) \
		$(use_with tiff) \
		$(use_with webp libwebp) \
		$(! use python && echo --without-python --disable-pyvips8) \
		$( (use python && python_is_python3) && echo --without-python --enable-pyvips8) \
		$( (use python && ! python_is_python3) && echo --with-python --disable-pyvips8)
}

src_prepare() {
	default

	# Set the version, to avoid a pointless warning.
	epatch "${FILESDIR}/force_version_for_Vips.py.patch"
}

src_install() {
	default
	use python && python_optimize
	prune_libtool_files
}