merlin-9999.ebuild

merlin-9999.ebuild (text/plain), 1.11 KB, created by José Romildo Malaquias on 2015-12-11 09:30:56 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit findlib elisp-common git-2

DESCRIPTION="Context sensitive completion for Ocaml in Vim and Emacs"
HOMEPAGE="https://github.com/the-lambda-church/merlin"
EGIT_REPO_URI="https://github.com/the-lambda-church/${PN}.git"

SLOT="0"
LICENSE="MIT"
KEYWORDS="~amd64 ~x86"
IUSE=emacs

RDEPEND=">=dev-lang/ocaml-4.01.0:=[ocamlopt]
	dev-ml/menhir[ocamlopt]
	dev-ml/yojson
	emacs? ( app-emacs/tuareg-mode )
"
DEPEND="${RDEPEND}"

SITEFILE="50${PN}-gentoo.el"

src_prepare() {
	sed -e "s|/emacs/site-lisp|/emacs/site-lisp/${PN}|g" -i Makefile || die
}

src_configure() {
	./configure \
		--prefix /usr \
		--vimdir /usr/share/vim/merlin \
		$(use_enable emacs compiled-emacs-mode) \
		|| die
}

src_compile() {
	emake
}

src_install() {
	emake install DESTDIR="${ED}"
	if use emacs; then
		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	else
		rm -rf "${ED}"/usr/share/emacs
	fi
	dodoc README.md TODO.md
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}