vice-1.15.ebuild

vice-1.15.ebuild (text/plain), 1.33 KB, created by Elias Kunnas on 2004-10-11 17:01:55 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/vice/vice-1.14-r1.ebuild,v 1.3 2004/08/02 09:37:50 dholm Exp $

inherit eutils games

DESCRIPTION="The Versatile Commodore 8-bit Emulator"
HOMEPAGE="http://www.viceteam.org/"
SRC_URI="ftp://ftp.funet.fi/pub/cbm/crossplatform/emulators/VICE/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ~ppc"
IUSE="sdl nls gnome arts Xaw3d"

RDEPEND="virtual/x11
	sdl? ( media-libs/libsdl )
	gnome? ( gnome-base/libgnomeui )
	arts? ( kde-base/arts )
	Xaw3d? ( x11-libs/Xaw3d )"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

src_compile() {
	local with_xaw3d=$(use_with Xaw3d) #needs lowercase X

	egamesconf \
		--enable-fullscreen \
		--disable-dependency-tracking \
		${with_xaw3d/X/x} \
		$(use_with sdl) \
		$(use_with gnome gnomeui) \
		$(use_with arts) \
		$(use_enable nls) \
		|| die
	emake || die "emake failed"
}

src_install() {
	local docdir="${D}${GAMES_LIBDIR}/${PN}/doc"

	make DESTDIR="${D}" install || die "make install failed"
	dohtml "${docdir}/"* || die "dohtml failed"
	dodoc \
		AUTHORS ChangeLog FEEDBACK README \
		"${docdir}/"{BUGS,NEWS,TODO} \
		"${docdir}/"{Walkthrough-Howto,serial,iec-bus,mon}.txt \
		"${docdir}/"{cbm_basic_tokens,drive_info,PETdoc,64doc}.txt
	rm -rf "${docdir}"
	prepgamesdirs
}