likwid-3.1.3.ebuild refined

likwid-3.1.3.ebuild (text/plain), 1.48 KB, created by Yixun Lan on 2015-03-05 06:20:41 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit eutils fcaps linux-info multilib

DESCRIPTION="A lightweight performance-oriented tool suite for x86 multicore environments"
HOMEPAGE="https://code.google.com/p/likwid/"
SRC_URI="http://ftp.fau.de/pub/likwid/likwid-${PV}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="-fortran"

RDEPEND="dev-lang/perl
	fortran? ( sys-devel/gcc[fortran] )"

DEPEND="${RDEPEND}
	sys-apps/sed"

CONFIG_CHECK="~X86_MSR"

FILECAPS=(
	cap_sys_rawio usr/sbin/likwid-accessD --
	cap_sys_rawio usr/bin/likwid-{perfctr,bench,powermeter}
)

src_prepare() {
	sed -e 's:^PREFIX = .*:PREFIX = '${D}'/usr:' \
		-e "/^LIBLIKWIDPIN/s|lib/|$(get_libdir)/|" \
		-i config.mk || die
	sed -e "s:\$(PREFIX)/lib:\$(PREFIX)/$(get_libdir):" \
		-i Makefile || die

	sed -e '/LIBS/aSHARED_LFLAGS += -Wl,-soname,$@' \
		-i make/include_GCC.mk || die
	sed -e '/^Q/d' -i Makefile || die
	sed -e 's/<DATE>/12.02.2014/g' \
		-e "s/VERSION/${PV}/g" \
		-i doc/* || die
	sed -e "/exeprog/s|TOSTRING(ACCESSDAEMON)|\"/usr/sbin/likwid-accessD\"|" \
		-i src/accessClient.c || die
	sed -e "/^CFLAGS/s|$| -Wa,--noexecstack|"  \
		-i make/include_GCC.mk || die

	epatch "${FILESDIR}/${P}-Makefile.patch"
}

src_configure() {
	if use fortran; then
		sed -i 's:^FORTRAN_INTERFACE = false:FORTRAN_INTERFACE = likwid.mod:' config.mk || die
	fi
}

src_install () {
	default
	use fortran && doins likwid.mod

	doman doc/*
}