[patch] diff -u patch of jack ebuilds

jack.patch (text/plain), 1.90 KB, created by Ian Delaney (RETIRED) on 2015-03-01 08:17:33 UTC

--- jack-3.1.1.ebuild	2010-05-29 05:08:01.000000000 +0800
+++ jack-3.1.1-r1.ebuild	2015-02-28 23:37:17.620797130 +0800
@@ -1,11 +1,13 @@
-# Copyright 1999-2010 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/jack/jack-3.1.1.ebuild,v 1.8 2010/05/28 21:08:01 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/jack/jack-3.1.1-r1.ebuild,v 1.6 2013/03/31 09:57:43 ago Exp $
 
-EAPI="3"
-PYTHON_DEPEND="2"
+EAPI=5
 
-inherit distutils
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1
 
 DESCRIPTION="A frontend for several cd-rippers and mp3 encoders"
 HOMEPAGE="http://www.home.unix-ag.org/arne/jack/"
@@ -13,36 +15,36 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="amd64 ppc ppc64 sparc x86"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
 IUSE=""
 
 DEPEND="sys-libs/ncurses"
 RDEPEND="${DEPEND}
-	dev-python/cddb-py
-	dev-python/id3-py
-	dev-python/pyid3lib
-	dev-python/pyvorbis
+	dev-python/cddb-py[${PYTHON_USEDEP}]
+	dev-python/id3-py[${PYTHON_USEDEP}]
+	dev-python/pyid3lib[${PYTHON_USEDEP}]
+	dev-python/pyvorbis[${PYTHON_USEDEP}]
 	media-libs/flac
 	media-sound/lame
 	media-sound/cdparanoia"
 
+PATCHES=( "${FILESDIR}"/${PN}-3.0.0-python26.patch )
+CFLAGS="${CFLAGS} -fno-strict-aliasing"
+
 pkg_setup() {
-	python_set_active_version 2
-	python_pkg_setup
+	python-single-r1_pkg_setup
 }
 
-src_install() {
-	distutils_src_install
-
-	dobin jack || die "dobin failed"
+src_prepare() {
+	python_fix_shebang .
+	distutils-r1_src_prepare
+}
 
-	insinto $(python_get_sitedir)
-	PYTHON_MODNAME="$(ls jack_*.py)"
-	doins ${PYTHON_MODNAME}
+src_install() {
+	local DOCS=( README doc/ChangeLog doc/TODO )
+	local HTML_DOCS=( doc/. )
+	distutils-r1_src_install
 
 	newman jack.man jack.1
-
-	dodoc README doc/ChangeLog doc/TODO
-
-	dohtml doc/*html doc/*css doc/*gif
+	python_doscript jack
 }