oregano-0.83.1.ebuild

oregano-0.83.1.ebuild (text/plain), 1.47 KB, created by Sławek Lis (RETIRED) on 2014-11-14 21:40:38 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-electronics/oregano/oregano-0.82.ebuild,v 1.6 2014/08/10 20:28:33 slyfox Exp $

EAPI="5"

inherit autotools eutils fdo-mime gnome2-utils waf-utils

DESCRIPTION="Oregano is an application for schematic capture and simulation of electrical circuits"
HOMEPAGE="https://github.com/drahnr/oregano"
SRC_URI="https://github.com/drahnr/${PN}/tarball/${PV} -> ${P}.tar.gz http://dev.gentoo.org/~slis/oregano/waf-1.7.15 -> waf"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

CDEPEND="dev-libs/libxml2:2
        x11-libs/goocanvas:2.0
        x11-libs/gtk+:3
        x11-libs/gtksourceview:3.0
        app-text/rarian"
DEPEND="${CDEPEND}
        virtual/pkgconfig"
RDEPEND="${CDEPEND}
        || ( gnome-base/dconf gnome-base/gconf )
        sci-electronics/electronics-menu"

S="${WORKDIR}/drahnr-oregano-4460753/"

src_prepare() {
        cp "${DISTDIR}/waf" "${S}"
        chmod +x "${S}/waf"
}

pkg_preinst() {
        gnome2_schemas_savelist
}

pkg_postinst() {
        gnome2_schemas_update
        fdo-mime_desktop_database_update
        elog "You'll need to emerge your prefered simulation backend"
        elog "such ngspice or gnucap for simulation to work."
        elog "As an alternative generate a netlist and use sci-electronics/spice"
        elog "from the command line for simulation."
}

pkg_postrm() {
        gnome2_schemas_update
}