sablotron-1.0.1-r1.ebuild

sablotron-1.0.1-r1.ebuild (text/plain), 1.53 KB, created by Mamoru KOMACHI (RETIRED) on 2004-09-01 23:29:47 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/sablotron/sablotron-1.0.1.ebuild,v 1.7 2004/08/02 02:50:04 tgall Exp $

inherit flag-o-matic libtool gnuconfig

MY_PN="Sablot"
MY_P="${MY_PN}-${PV}"
S=${WORKDIR}/${MY_P}

DESCRIPTION="An XSLT Parser in C++"
HOMEPAGE="http://www.gingerall.com/charlie-bin/get/webGA/act/sablotron.act"
SRC_URI="http://download-1.gingerall.cz/download/sablot/${MY_P}.tar.gz"

# Sablotron can optionally be built under GPL, using MPL for now
LICENSE="MPL-1.1"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc perl javascript"

DEPEND=">=dev-libs/expat-1.95.6-r1
	>=dev-perl/XML-Parser-2.3
	javascript? ( dev-lang/spidermonkey )"

DOCS="INSTALL README README_JS RELEASE src/TODO"

src_compile() {

	# Detect mips systems properly
	gnuconfig_update

	# Please do not remove, else we get references to PORTAGE_TMPDIR
	# in /usr/lib/libsablot.la ...
	elibtoolize

	# rphillips, fixes bug #3876
	# this is fixed for me with apache2, but keeping it in here
	# for apache1 users and/or until some clever detection
	# is added <[e-mail]>
	append-ldflags -lstdc++

	if use javascript ; then
		append-flags -I/usr/lib/mozilla/include/js
		export CPPFLAGS="${CPPFLAGS} -I/usr/lib/mozilla/include/js"
	fi

	econf $(use_enable perl perlconnect) \
		$(use_enable javascript) \
		$(use_with doc html-dir ${D}/usr/share/doc/${P}/html) \
		|| die "Configure failed"
	emake || die "Make failed"
}

src_install() {
	einstall || die "Install failed"
	dodoc ${DOCS}
}