picolisp-3.1.8.ebuild

picolisp-3.1.8.ebuild (text/plain), 2.32 KB, created by Constantine Bytensky on 2014-10-17 20:32:57 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit eutils bash-completion-r1

if [[ ${PV} == 9999 ]] ; then
	inherit mercurial
	EHG_REPO_URI="https://code.google.com/p/picolisp/"
else
	SRC_URI="http://software-lab.de/picoLisp-${PV}.tgz"
	KEYWORDS="~amd64 ~x86"
fi

SRC_URI+=" amd64? ( http://software-lab.de/x86-64.linux.tgz )"

DESCRIPTION="A fast and lightweight Lisp interpreter"
HOMEPAGE="http://picolisp.com/"

LICENSE="MIT"
SLOT="0"
IUSE="bash-completion doc examples"

QA_PREBUILT="*"

S="${WORKDIR}/picoLisp"

src_unpack() {
	unpack ${A}
	mercurial_src_unpack
}

src_prepare() {
	sed -i "s#!bin/picolisp lib.l#!/usr/bin/picolisp /usr/lib/picolisp/lib.l#" bin/psh bin/replica bin/watchdog misc/bigtest misc/calc misc/chat misc/mailing games/xchess games/xchess games/xchess
	sed -i "s# test -x /usr/bin/picolisp# false#" src64/mkAsm
	epatch_user
}

src_compile() {
	if use amd64; then
		cd src64
		einfo 'Phase 1: building picolisp with prebuild *.s files'
		cp ../../src64/*.s .
		emake
		einfo 'Phase 2: building picolisp using picolisp'
		emake clean
		emake
	else
		cd src
		emake
	fi
}

src_install() {
	DLIB=/usr/$(get_libdir)/picolisp
	dobin bin/picolisp bin/pil
	exeinto $DLIB/bin
	doexe bin/psh bin/replica bin/watchdog
	insinto $DLIB
	use bash-completion && newbashcomp lib/bash_completion "${PN}"
	rm -rf lib/bash_completion lib/el
	doins -r *.l *.css lib
	if use amd64; then
		DSRC=/usr/$(get_libdir)/picolisp/src64
		insinto $DSRC
		doins -r src64/*.l src64/lib
		insinto $DSRC/arch
		doins -r src64/arch/x86-64.l
		insinto $DSRC/sys
		doins -r src64/sys/x86-64.linux.*
	fi
	doman man/*/*
	if use doc; then
		dodoc CHANGES COPYING CREDITS INSTALL README
		DDOC=/usr/share/doc/${PF}
		insinto $DDOC
		doins doc/quine doc/db doc/travel doc/utf8 doc/vim-tsm
		dohtml doc/*
		insinto $DDOC/html
		doins doc/family.l doc/shape.l doc/fun.l doc/hello.l
		if use amd64; then
			doins doc/family64.tgz
			insinto $DDOC
			doins -r doc64
		else
			doins doc/family.tgz
			insinto $DDOC
			doins doc/structures
		fi
		dosym $DDOC/html $DLIB/doc
	fi
	if use examples; then
		DSHARE=/usr/share/picolisp
		insinto $DSHARE
		doins -r app games loc misc opt
		exeinto $DSHARE/misc
		doexe misc/bigtest misc/calc misc/chat misc/mailing
		exeinto $DSHARE/games
		doexe games/xchess
	fi
}