eclipse-ecj-4.4.ebuild

eclipse-ecj-4.4.ebuild (text/plain), 1.56 KB, created by William L. Thomson Jr. on 2014-07-22 19:11:59 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/eclipse-ecj/eclipse-ecj-3.6.ebuild,v 1.1 2010/12/21 07:40:35 ali_bush Exp $

EAPI="5"

inherit java-pkg-2 java-ant-2

MY_PN="ecj"
DMF="R-${PV}-201406061215"
S="${WORKDIR}"

DESCRIPTION="Eclipse Compiler for Java"
HOMEPAGE="http://www.eclipse.org/"
SRC_URI="http://download.eclipse.org/eclipse/downloads/drops4/${DMF}/${MY_PN}src-${PV}.jar"

LICENSE="EPL-1.0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
SLOT="4.4"
IUSE="+ant userland_GNU"

CDEPEND="
	|| ( app-admin/eselect-java app-admin/eselect-ecj )"

DEPEND="${CDEPEND}
	app-arch/unzip
	>=virtual/jdk-1.6
	userland_GNU? ( sys-apps/findutils )"
RDEPEND="${CDEPEND}
	>=virtual/jre-1.6"
PDEPEND="ant? ( ~dev-java/ant-eclipse-ecj-${PV} )"

EANT_BUILD_TARGET="build"

java_prepare() {
	# These have their own package.
	rm -f org/eclipse/jdt/core/JDTCompilerAdapter.java || die
	rm -fr org/eclipse/jdt/internal/antadapter || die

	# remove manifest file copy to bad location
	sed -i '/<copy tofile=/d' build.xml || die
}

src_install() {
	java-pkg_dolauncher ${MY_PN}-${SLOT} --main \
		org.eclipse.jdt.internal.compiler.batch.Main

	# disable the class version verify, this has intentionally
	# some classes with 1.6, but most is 1.4
	JAVA_PKG_STRICT="" java-pkg_dojar ${MY_PN}.jar
}

pkg_postinst() {
	einfo "To select between slots of ECJ..."
	einfo " # eselect ecj"

	eselect ecj update ecj-${SLOT}
}

pkg_postrm() {
	eselect ecj update
}