New cleaned up ebuild for 1.0.0

eternal-lands-1.0.0.ebuild (text/plain), 2.28 KB, created by Joel Martin (RETIRED) on 2004-08-17 12:52:10 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="Eternal Lands is an online MMORPG written in C and SDL"
HOMEPAGE="http://www.eternal-lands.com"
TMP_PV=${PV%_p*}
SRC_URI="http://el.tfm.ro/el_${TMP_PV//.}.zip ftp://ftp.berlios.de/pub/elc/elc_${PV//.}.tgz"

LICENSE="eternal_lands"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="virtual/x11
		virtual/opengl
		>=media-libs/libsdl-1.2.5
		>=media-libs/sdl-net-1.2.5
		>media-libs/openal-20020127
		media-libs/libvorbis
		>=dev-libs/libxml2-2.6.7"

RDEPEND=${DEPEND}

src_unpack() {
	unpack "el_${TMP_PV//.}.zip"
	unpack "elc_${PV//.}.tgz"
}

src_compile() {
	cd "${WORKDIR}/elc"
	sed -e "s@_CFLAGS=\$(PLATFORM) -O3 -fomit-frame-pointer -ffast-math -pipe@_CFLAGS=${CFLAGS}@g" -e 's@OPTIONS=@OPTIONS=-DDATA_DIR="\\"${GAMES_DATADIR}/${PN}/\\"" @g' -e "w Makefile" Makefile.linux > /dev/null
	make release || die "make failed!"
	cp el.x86.linux.bin ../el.x86.linux.bin
	cp eternal_lands_license.txt ../LICENSE
	sed -e 's/#browser/browser/g' -e 's/browser = mozilla/#browser = mozilla/g' -e "s@data_dir = /usr/local/games/el/@#data_dir = ${GAMES_DATADIR}/${PN}/@g" -e "w ../el.ini" el.ini > /dev/null
	cd ..
	mv license.txt EULA
}

src_install () {
	cd "${WORKDIR}"
	insinto ${GAMES_DATADIR}/${PN}
	newgamesbin el.x86.linux.bin el
	dodoc changes.txt faq.txt readme.txt LICENSE EULA
	doins el.ini entrable.lst knowledge.lst harvestable.lst el_icon.png icon.bmp global_filters.txt global_ignores.txt || die "Files failed to be installed"
	cd 2dobjects
	for file in *
	do
		insinto  ${GAMES_DATADIR}/${PN}/2dobjects/$file/
		doins $file/*
	done
	cd ..
	cd 3dobjects
	for file in *
	do
		insinto  ${GAMES_DATADIR}/${PN}/3dobjects/$file/
		doins $file/*
	done
	cd ..
	insinto ${GAMES_DATADIR}/${PN}/Encyclopedia/
	doins Encyclopedia/*
	insinto ${GAMES_DATADIR}/${PN}/Encyclopedia/images/
	doins Encyclopedia/images/*
	insinto ${GAMES_DATADIR}/${PN}/maps/
	doins maps/*
	insinto ${GAMES_DATADIR}/${PN}/md2/
	doins md2/*
	insinto ${GAMES_DATADIR}/${PN}/sound/
	doins sound/*
	insinto ${GAMES_DATADIR}/${PN}/textures/
	doins textures/*
	insinto ${GAMES_DATADIR}/${PN}/tiles/
	doins tiles/*
} 

pkg_postinst() {
	einfo "To run the game: el"
	einfo "Copy el.ini to ~/.elc/ to make per-user changes."
}