grass-6.4.3.ebuild

grass-6.4.3.ebuild (text/plain), 9.67 KB, created by Ulf Norberg on 2014-02-07 13:23:15 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

PYTHON_COMPAT=( python2_{5..7} )
# Use the following to find all lang:
# find locale/po/ -name "*.po" -printf "%f\n" | sed -n 's/grass[a-z]*_\(.*\)\.po/\1/p' |sort -u
PLOCALES="am ar br cs de el es fr hi id it ja ko lv ml mr nl pl pt pt_BR ro ru sl th tr vi zh"
inherit eutils gnome2 l10n multilib python-single-r1 versionator wxwidgets

MY_PM=${PN}$(get_version_component_range 1-2 ${PV})
MY_PM=${MY_PM/.}
MY_P=${P/_rc/RC}

DESCRIPTION="A free GIS with raster and vector functionality, as well as 3D vizualization"
HOMEPAGE="http://grass.osgeo.org/"
SRC_URI="http://grass.osgeo.org/${MY_PM}/source/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="6"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="X cairo colors cxx doc ffmpeg fftw gem geos gmath jpeg motif mysql nls odbc opengl png postgres python readline sqlite tcltk tiff truetype wxpsmaps wxwidgets"

RDEPEND="
	sci-libs/gdal
	sci-libs/proj
	sys-libs/ncurses
	sys-libs/zlib
	cairo? ( x11-libs/cairo[X?,opengl?] )
	ffmpeg? ( >=virtual/ffmpeg-0.10 )
	fftw? ( sci-libs/fftw:3.0 )
	geos? ( sci-libs/geos )
	gmath? (
		sci-libs/blas-reference
		sci-libs/lapack-reference
	)
	jpeg? ( virtual/jpeg )
	mysql? ( virtual/mysql )
	odbc? ( dev-db/unixODBC )
	opengl? ( virtual/opengl )
	png? ( media-libs/libpng )
	postgres? ( >=dev-db/postgresql-base-8.4 )
	python? (
		${PYTHON_DEPS}
		wxwidgets? (
			>=dev-python/wxpython-2.8.1.1[${PYTHON_USEDEP},cairo,opengl?]
			>=dev-python/numpy-1.0.4[${PYTHON_USEDEP}]
			wxpsmaps? ( virtual/python-imaging[${PYTHON_USEDEP}] )
		)
	)
	readline? ( sys-libs/readline )
	sqlite? ( dev-db/sqlite:3 )
	tcltk? (
		>=dev-lang/tcl-8.4
		>=dev-lang/tk-8.4
	)
	tiff? ( media-libs/tiff )
	truetype? ( media-libs/freetype:2 )
	X? (
		x11-libs/libICE
		x11-libs/libSM
		x11-libs/libX11
		x11-libs/libXaw
		x11-libs/libXext
		x11-libs/libXmu
		x11-libs/libXp
		x11-libs/libXpm
		x11-libs/libXt
		motif? (
			>=x11-libs/motif-2.3:0
			opengl? ( x11-libs/libGLw )
		)
	)"

DEPEND="${RDEPEND}
	virtual/pkgconfig
	sys-devel/flex
	sys-devel/gettext
	sys-devel/bison
	doc? ( app-doc/doxygen )
	wxwidgets? ( dev-lang/swig )
	X? (
		x11-proto/xextproto
		x11-proto/xproto
	)"

REQUIRED_USE="
	motif? ( X )
	opengl? ( X )
	wxwidgets? ( X python )
	wxpsmaps? ( wxwidgets )
"

S="${WORKDIR}/${MY_P}"

grass_dir=usr/$(get_libdir)/${MY_PM}
DOCS=(
	"${ED}"/${grass_dir}/AUTHORS
	"${ED}"/${grass_dir}/CHANGES
	"${ED}"/${grass_dir}/COPYING
	"${ED}"/${grass_dir}/REQUIREMENTS.html
	"${ED}"/${grass_dir}/contributors.csv
	"${ED}"/${grass_dir}/contributors_extra.csv
	"${ED}"/${grass_dir}/translators.csv )
HTML_DOCS=( "${ED}"/${grass_dir}/docs/html/ )

pkg_setup() {
	# Make sure grass is built using python-2 even when python-3 is
	# default on the system (see #483082)
	use python && python-single-r1_pkg_setup
}

src_prepare() {
	EPATCH_SUFFIX="patch"
	EPATCH_SOURCE="${FILESDIR}"
	EPATCH_FORCE="yes"
	use colors || EPATCH_EXCLUDE="${PN}-colorize.patch"
	EPATCH_MULTI_MSG="Applying patches from ${EPATCH_SOURCE} ..."
	epatch

	# GEM may not be very appropriate to include in a package at
	# all... At least not if it installs the modules to
	# /usr/lib64/grass64 (but I have not tested if that i the case)
	#
	if ! use gem; then
		# Remove building and installing block for GEM in the Makefile:
		sed ':t /ifeq/,/endif/ { /endif/!{ $!{ N; bt; }; }; /gem/d;}' -i Makefile

		sed -i '\/HTMLDIR\/gem/d' tools/build_html_index.sh
	fi

	# patch ffmpeg includes (see #466388 - also added mathematics.h)
	sed -e 's:\(avcodec\|avformat\|swscale\)\.h:lib\1/\0:' \
		-e 's:avio\.h:libavformat/\0:' \
		-e 's:mathematics\.h:libavutil/\0:' \
		-i configure.in \
		-i configure \
		-i lib/ogsf/gsd_img_mpeg.c

	# Set INSTDIR in configure so that various config files get the right path
	sed -r -e "/else/,/fi/ s:^( +INSTDIR=).*$:\1\"/usr/$(get_libdir)/${MY_PM}\":" \
		-i configure -i configure.in

	if ! use tcltk; then
		sed -i 's/tcltk//' gui/Makefile
		sed -i '/^[[:space:]].*\.tcl \\/d' lib/init/Makefile
		sed -i '/gtcltk/d' lib/Makefile
		sed -i 's/gui.tcl//' lib/gis/Makefile
		sed -i '/d.rast.edit/d' scripts/Makefile
		sed -i '/r.li$/d' raster/Makefile
		sed -i '/bwidget/d' Makefile
		sed -i '/bwidget/d' lib/external/Makefile
	fi

	if ! use opengl; then
		# These ctypes modules will not build correctly without opengl:
		sed -i '/MODULES/,/^$/ s:ogsf\|nviz::g' lib/python/ctypes/Makefile

		# Gets rid of "3D view mode: No module named ogsf" message when
		# wxpython starts and nviz is compiled without opengl
		sed -i -e '/grass.lib.ogsf/d' -e '/grass.lib.nviz/d' gui/wxpython/nviz/wxnviz.py

		# Replaces the html-nonviz.patch:
		sed -i '/nviz/d' tools/build_html_index.sh
	fi

	# This seems to be necessary to be able to use PIL import (needed
	# for wxpsmap):
	sed -i 's/\(^  *\)\(import Image.*$\)/\1from PIL \2/' \
		gui/wxpython/psmap/utils.py

	# Change DOC_BASE for man & html pages in g.manual:
	sed -i -e "s:\(.*=\"\).*GRASS_DOC_BASE.*\(/man/man1.*$\):\1/usr/share\2:" \
		-e "s:\(.*=\"\).*GRASS_DOC_BASE.*\(/html.*$\):\1/usr/share/doc/${PF}\2:" \
		-e "s:\$1\.1:\$1.1grass:g" -e "s:\.gz:.bz2:g" \
		scripts/g.manual/g.manual

	use wxwidgets || sed -i 's/wxpython//' gui/Makefile

	if use nls; then
		# pt_BR is broken
		for po in $(find locale/po -type f -name '*_pt_br*'); do mv ${po} ${po/_pt_br/_pt_BR}; done
		del_locale_po() {
			rm -f "${S}"/locale/po/grass*_${1}.po || die
		}
		l10n_for_each_disabled_locale_do del_locale_po || die
	fi

}

src_configure() {
	# Dont know if this has any real effekt...
	( use amd64 || use ppc64 ) && myconf+=" --enable-64bit"

	if use X; then
		myconf+="
			$(use_with motif)
			$(use_with opengl)
			$(use_with tcltk)
			--with-x"

		use motif && use opengl && myconf+=" --with-glw"

		if use wxwidgets; then
			WX_GTK_VER=2.8
			need-wxwidgets unicode
			myconf+=" --with-wxwidgets=${WX_CONFIG}"
		else
			myconf+=" --without-wxwidgets"
		fi
	else
		myconf+="
			--without-glw
			--without-opengl
			--without-tcltk
			--without-wxwidgets
			--without-x"
	fi

	# gmath is not really very usefull in grass64, see
	# <http://grass.osgeo.org/grass64/source/REQUIREMENTS.html>, so
	# perhaps the gmath USE-flag should be removed.
	if use gmath; then
		myconf+="
			--with-blas
			--with-blas-libs=/usr/$(get_libdir)/blas/reference
			--with-lapack
			--with-lapack-libs=/usr/$(get_libdir)/lapack/reference
		"
	fi

	econf \
		--with-libs=/usr/$(get_libdir) \
		--with-gdal=$(type -P gdal-config) \
		--with-curses \
		--with-proj \
		--with-proj-share="/usr/share/proj/" \
		--enable-shared \
		$(use_with cairo) \
		$(use_with cxx) \
		$(use_with fftw) \
		$(use_with ffmpeg) \
		$(use_with geos ) \
		$(use_with jpeg) \
		$(use_with mysql) \
		--with-mysql-includes=/usr/include/mysql \
		--with-mysql-libs=/usr/$(get_libdir)/mysql \
		$(use_with nls) \
		$(use_with odbc) \
		$(use_with png) \
		$(use_with postgres) \
		$(use_with python python "${PYTHON}-config") \
		$(use_with readline) \
		$(use_with sqlite) \
		$(use_with tiff) \
		$(use_with truetype freetype) \
		--with-freetype-includes=/usr/include/freetype2 \
		--enable-largefile \
		${myconf}
}

if use doc; then
	src_compile() {
		default
		emake htmldocs
	}
fi

src_install() {
	emake DESTDIR="${D}" install
	einstalldocs
	rm "${DOCS[@]}" || die

	pushd "${ED}"/${grass_dir} &> /dev/null
	rm GPL.TXT
	rm -r docs || die

	if use doc; then
		docinto programmers.manual
		dohtml -r ${S}/html/
	fi

	einfo "Updating man pages."
	# Rename man pages from *.1 to *.1grass.  See #381599, but here it
	# is done for all man pages (as Debian do)
	find man/man1/ -type f -name '*.1' -exec \
		mv {}{,grass} \; || die
	# Update sections in man pages:
	find man/man1/ -type f -name '*.1grass' -exec \
		sed -i 's/^.TH \(.*\) 1/.TH \1 1grass/' {} \; || die
	# Install man-pages to the proper place (without -i18n="" doman will
	# interpret some of the names as languages)
	find man/man1/ -type f -name '*.1grass' -exec \
		doman -i18n="" {} \; || die
	rm -r man || die

	if use nls; then
		# pt_BR is broken
		#mv locale/pt_br locale/pt_BR || die
		[[ -d locale ]] && ( mv locale "${ED}"/usr/share/ || die )
	fi
	# doheader (EAPI 5)
	doheader -r include/grass
	rm -r include/grass || die
	use gem || rm -r include || die

	# Only needed during build:
	rm tools/g.html2man tools/mkhtml.sh

	popd &> /dev/null

	local grass_gui
	if use wxwidgets; then
		grass_gui=wxpython
	elif use tcltk; then
		grass_gui=tcltk
	else
		grass_gui=text
	fi

	einfo "Setting default GRASS GUI to '${grass_gui}'"
	sed -i "1,\$s:^DEFAULT_GUI.*:DEFAULT_GUI=\"${grass_gui}\":" \
		"${ED}"${grass_dir}/etc/Init.sh || die

	# Make sure GRASS use the correct python-version.
	if use python; then
		einfo "Setting GRASS_PYTHON=${EPYTHON}"
		# If the following is not enough, try python_fix_shebang from
		# python-single-r1 eclass.
		sed -i "s:\(^  *GRASS_PYTHON=\)python$:\1${EPYTHON}:" \
			"${ED}"${grass_dir}/etc/Init.sh || die

		if false; then
			# Any advantage of doing this? (qgis also uses
			# python_optimize)...:
			einfo "Optimzing python modules"
			local python_dirs
			python_dirs=$(find "${ED}"/${grass_dir}/ -name "*.pyc" -printf "%h\n" | sort -u)
			find "${ED}"/${grass_dir}/ -name "*.pyc" -exec rm {} \; || die
			python_optimize ${python_dirs}
		fi
	fi

	if use X; then
		newicon gui/icons/${PN}-48x48.png ${PN}.png
		make_desktop_entry grass64 "Grass ${PV}" "${PN} -${grass_gui}" "Science;Education;" "Terminal=true"
	fi

	# install .pc file so other apps know where to look for grass
	insinto /usr/$(get_libdir)/pkgconfig/
	doins grass.pc

	# fix weird +x on tcl scripts
	find "${D}" -name "*.tcl" -exec chmod +r-x '{}' \;
}

pkg_postinst() {
	if use X; then
		fdo-mime_desktop_database_update
		gnome2_icon_cache_update
	fi
}

pkg_postrm() {
	if use X; then
		fdo-mime_desktop_database_update
		gnome2_icon_cache_update
	fi
}