irker-1.20.ebuild

irker-1.20.ebuild (text/plain), 1.59 KB, created by Bertrand Jacquin on 2013-10-05 17:40:00 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/irker/irker-1.20.ebuild,v 1.1 2013/05/22 03:40:55 patrick Exp $

EAPI=5
PYTHON_COMPAT=( python{2_7,2_6} )

inherit python-single-r1 systemd eutils

DESCRIPTION="Submission tools for IRC notifications"
HOMEPAGE="http://www.catb.org/esr/irker/"
SRC_URI="http://www.catb.org/esr/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="app-text/docbook-xml-dtd:4.1.2
	app-text/xmlto"
RDEPEND="=dev-lang/python-2*
	dev-python/irc"

src_prepare() {
	# https://gitorious.org/irker/irker/merge_requests/25
	epatch "${FILESDIR}/0001-Register-author_name-as-author-instead-of-email-user.patch"
	# https://gitorious.org/irker/irker/merge_requests/23
	epatch "${FILESDIR}/0002-Fixed-utf-8-handling-in-metadata.patch"
	# https://gitorious.org/irker/irker/merge_requests/24
	epatch "${FILESDIR}/0003-Git-Fixed-presentation-of-branches-containing-front-.patch"

	# Rely on systemd eclass for systemd service install
	sed -i -e "/^SYSTEMDSYSTEMUNITDIR/d" Makefile

	# Prefix support
	sed -i -e "/^ExecStart=/ s:=/:=${EROOT}:" irkerd.service
}

src_install() {
	emake DESTDIR="${ED}" install

	python_doscript "${ED}/usr/bin/irkerd"
	# Not installed with the default Makefile
	python_doscript irk irkerhook.py

	newinitd "${FILESDIR}/irkerd.initd" irkerd
	newconfd "${FILESDIR}/irkerd.confd" irkerd

	systemd_dounit irkerd.service

	dodoc NEWS README hacking.txt security.txt
	dohtml irkerd.html irkerhook.html

	docinto examples
	dodoc filter-example.py filter-test.py
}