pipelight-9999.ebuild

pipelight-9999.ebuild (text/plain), 1.16 KB, created by James Le Cuirot on 2013-08-19 06:41:02 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
EGIT_REPO_URI="https://bitbucket.org/mmueller2012/pipelight.git"

inherit multilib toolchain-funcs git-2

DESCRIPTION="Run Silverlight applications directly in the browser using Wine"
HOMEPAGE="https://launchpad.net/pipelight"

LICENSE="MPL-1.1 GPL-2.0 LGPL-2.1"
SLOT="0"
KEYWORDS="-* ~amd64"
IUSE=""

RDEPEND="app-emulation/wine
	x11-libs/libX11"

DEPEND="${RDEPEND}"

src_prepare() {
	local TARGET="mingw32"
	local VERSION=$(CHOST="${TARGET}" gcc-fullversion)
	local GCCLIB="${EPREFIX}/usr/$(get_libdir)/gcc/${TARGET}/${VERSION}"

	sed -i "s:/lib/mozilla/:/$(get_libdir)/nsbrowser/:g" \
		Makefile || die

	sed -i \
		-e "s:i686-w64-mingw32:${TARGET}:g" \
		-e "s:-std=c++0x:-D_WIN32_WINNT=0x0502 -std=gnu++0x:g" \
		src/windows/Makefile || die

	sed -i -r "s:(#define DEFAULT_GCC_RUNTIME_DLL_SEARCH_PATH ).*:\1\"${GCCLIB}\":g" \
		src/linux/configloader.h || die

	sed -i -r "s:^(winePath[^=]*=).*:\1 wine:" \
		share/pipelight || die
}

src_configure() {
	# Don't use econf, not a normal configure script.
	./configure --prefix="${EPREFIX}/usr" || die
}