bcfg2-1.3.1-r3.ebuild

bcfg2-1.3.1-r3.ebuild (text/plain), 2.04 KB, created by Alexandr Tiurin on 2013-05-22 11:02:55 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: 

EAPI="5"

PYTHON_DEPEND="2:2.6"
SUPPORT_PYTHON_ABIS="1"
# ssl module required.
RESTRICT_PYTHON_ABIS="2.4 2.5 3.*"

inherit distutils eutils

DESCRIPTION="Configuration management tool"
HOMEPAGE="http://bcfg2.org"
SRC_URI="ftp://ftp.mcs.anl.gov/pub/bcfg/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
IUSE="doc cheetah genshi server"

DEPEND="dev-python/setuptools
	doc? ( dev-python/sphinx )"
RDEPEND="app-portage/gentoolkit
	cheetah? ( dev-python/cheetah )
	genshi? ( dev-python/genshi )
	dev-python/pyinotify
	dev-python/m2crypto
	server? (
		virtual/fam
		dev-python/cherrypy
		dev-python/django[sqlite]
		dev-python/lxml
		dev-python/nose
		dev-python/python-daemon
		dev-python/south
		dev-libs/libgamin[python]
		media-gfx/graphviz )"

PYTHON_MODNAME="Bcfg2"

distutils_src_install_post_hook() {
	if ! use server; then
		rm -f "$(distutils_get_intermediate_installation_image)${EPREFIX}/usr/sbin/bcfg2-"*
	fi
}

src_prepare() {
	epatch "${FILESDIR}/${P}-portagefix.patch"
}

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Building Bcfg2 documentation"
		PYTHONPATH="build-$(PYTHON -f --ABI)" \
			sphinx-build doc doc_output || die
	fi
}

src_install() {
	distutils_src_install --record=PY_SERVER_LIBS --install-scripts "${EPREFIX}/usr/sbin"

	if ! use server; then
		rm -rf "${ED}usr/share/bcfg2" || die
		rm -rf "${ED}usr/share/man/man8" || die
	else
		newinitd "${FILESDIR}/${PN}-server-1.3.rc" bcfg2-server
		newinitd "${FILESDIR}/${PN}-report-collector-1.3.rc" bcfg2-report-collector
	fi

	insinto /etc
	doins examples/bcfg2.conf

	if use doc; then
		pushd doc_output > /dev/null
		insinto /usr/share/doc/${PF}/html
		doins -r [a-z]* _images _static || die "Failed to install documentation"
		popd > /dev/null
	fi
}

pkg_postinst () {
	distutils_pkg_postinst

	if use server; then
		einfo "If this is a new installation, you probably need to run:"
		einfo "    bcfg2-admin init"
	fi
}