stratagus-2.1_pre1.ebuild

stratagus-2.1_pre1.ebuild (text/plain), 1.24 KB, created by Martti Rannanjärvi on 2004-06-24 03:07:27 UTC

# Copyright 2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: Exp $

inherit games 

DESCRIPTION="A realtime strategy game engine"
HOMEPAGE="http://www.stratagus.org/"
SRC_URI="mirror://sourceforge/${PN}/${P/_}-src.tar.gz"
LICENSE="GPL-2"

KEYWORDS="~x86"
IUSE="doc flac mad mikmod oggvorbis"
SLOT="0"
		
RDEPEND="virtual/glibc
	virtual/x11
	app-arch/bzip2 
	dev-lang/lua
	media-libs/libpng
	media-libs/libsdl
	sys-devel/gcc
	sys-libs/zlib
	flac? ( media-libs/flac )
	mad? ( media-sound/libmad )
	mikmod? ( media-libs/libmikmod )
	oggvorbis? (
		media-libs/libogg
		media-libs/libvorbis
	)"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

S="${WORKDIR}/stratagus-040618"

src_unpack() {
	unpack ${A}
	
	sed -i ${S}/configure.in \
		-e "s:\(DEBUG_CFLAGS=\).*:\1\"${CFLAGS}\":"
}

src_compile() {
	autoconf
	
	econf \
		$(use_with oggvorbis ogg) \
		$(use_with mikmod) \
		$(use_with flac) \
		$(use_with mad) 
	
	emake -j1 || die "emake failed"

	use doc && {
		emake doc || die "making source documentation failed"
	}
}

src_install() {
	exeinto ${GAMES_LIBDIR}
	doexe stratagus
	prepgamesdirs
	
	dodoc README
	mv doc/ ${D}/usr/share/doc/${PF}/

	use doc && {
		doman srcdoc/man/man3/*
		dohtml srcdoc/html/*
	}
}