ntrack-016.ebuild

ntrack-016.ebuild (text/plain), 1.14 KB, created by Sergey Popov (RETIRED) on 2013-02-05 10:27:01 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

AUTOTOOLS_AUTORECONF=1
inherit autotools-utils

DESCRIPTION="Network connectivity tracking library for desktop applications"
HOMEPAGE="http://launchpad.net/ntrack"
SRC_URI="http://launchpad.net/ntrack/main/${PV}/+download/${P}.tar.gz"

LICENSE="|| ( GPL-3 LGPL-3 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="glib libnl qt4 python static-libs"

RDEPEND="
	glib? ( dev-libs/glib:2 )
	python? ( dev-python/pygobject:2 )
	libnl? ( dev-libs/libnl )
	qt4? ( x11-libs/qt-core:4 )
	"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

REQUIRED_USE="python? ( glib )"

DOCS=( ChangeLog NEWS README )

src_prepare() {
	# drop -Werror
	sed -i -e 's/-Werror//' {qt4,qt4/test,modules,gobject,gobject/test,common,common/test,glib,glib/test}/Makefile.am || die 'sed failed'

	autotools-utils_src_prepare
}

src_configure() {
	local myeconfargs=(
		--enable-backend=$(usex libnl 'libnl' 'rtnetlink' '' '')
		--enable-developer-build
		$(use_with glib glib2)
		$(use_with glib gobject)
		$(use_with python pygobject)
		$(use_with qt4)
	)
	autotools-utils_src_configure
}