virtualjaguar-2.0.2.ebuild

virtualjaguar-2.0.2.ebuild (text/plain), 1.11 KB, created by Mr. Bones. (RETIRED) on 2013-01-05 05:08:01 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
inherit eutils qt4-r2 games

DESCRIPTION="an Atari Jaguar emulator"
HOMEPAGE="http://www.icculus.org/virtualjaguar/"
SRC_URI="http://www.icculus.org/virtualjaguar/tarballs/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="jaguar-cd"

RDEPEND="media-libs/libsdl[audio,joystick,opengl,video]
	sys-libs/zlib
	virtual/opengl
	x11-libs/qt-gui
	x11-libs/qt-opengl
	jaguar-cd? ( dev-libs/libcdio )"
DEPEND="${RDEPEND}
	>=sys-devel/gcc-4.4"

S=${WORKDIR}/${PN}

src_prepare() {
	sed -i \
		-e '/fast-math/s/-O2.*//' \
		-e '/^LIBS/s/$/ -lz/' \
		virtualjaguar.pro || die
	eqmake4 virtualjaguar.pro -o makefile-qt
}

src_compile() {
	emake -j1
}

src_install() {
	dogamesbin ${PN}
	dodoc docs/{README,TODO,WHATSNEW}
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	elog "The ${PN} ROM path is no-longer hardcoded, "
	elog "set it from within, the ${PN} GUI."
	elog
	elog "The ROM extension supported by ${PN} is .j64, "
	elog ".jag files will be interpreted as Jaguar Server executables."
}