The ebuild

qtpoveditor-0.3.4.ebuild (text/plain), 1.92 KB, created by Alastair Murray on 2004-06-15 17:34:54 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

RESOURCES_PN="${PN}_ressources"
RESOURCES_PV="20040321"

DECRIPTION="A qt based scene editor for povray with syntax highlighting."
HOMEPAGE="http://qtpoveditor.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${PN}_v${PV}.tar.bz2
mirror://sourceforge/${PN}/${RESOURCES_PN}_${RESOURCES_PV}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"

KEYWORDS="~x86"
IUSE="nls"
DEPEND=">=x11-libs/qt-3.2.3-r1
	>=sys-apps/sed-4"
RDEPEND=">=x11-libs/qt-3.2.3-r1
	>=media-gfx/povray-3.50c"

S=${WORKDIR}/${PN}

src_compile() {
	qmake qtpoveditor.pro || die "qmake failed"
	# Prevent attempted Sandbox violations:
	addpredict ${QTDIR}/etc/settings
	# Add our CFLAGS and CXXFLAGS to the supplied ones:
	sed -i -e "s,^\(CFLAGS *=.*\),\1 ${CFLAGS}," Makefile
	sed -i -e "s,^\(CXXFLAGS *=.*\),\1 ${CXXFLAGS}," Makefile
	emake || die "emake failed"
}

src_install() {
	dobin qtpoveditor
	if use nls ; then
	  # There is a french translation available:
		dodir /usr/share/${PN}/translations/
		cp translations/*.qm  ${D}/usr/share/${PN}/translations/
	fi
	dodoc README gpl.txt
	# This is all additional resources installation now:
	cd ../${RESOURCES_PN}/
	dohtml help/*
	dodir /usr/share/doc/${PF}/html/images/
	cp help/images/* ${D}/usr/share/doc/${PF}/html/images/
	dodir /usr/share/${PN}/InsertMenu/
	cp -R Insert\ Menu/*  ${D}/usr/share/${PN}/InsertMenu/
	cp *.txt ${D}/usr/share/${PN}/
}

pkg_postinst(){
	if use nls ; then
		einfo " "
		einfo "A French translation is also available, use it by going to the"
		einfo "Edit menu, selecting Preferences, Misc, and setting Language"
		einfo "Pack to /usr/share/qtpoveditor/translations/lang_pack_fr.qm"
	fi
	einfo " "
	einfo "Resources such as keyword lists and an Insert Menu pack can be"
	einfo "found in /usr/share/qtpoveditor/"
	einfo "These can be specified in by going to Preferences in the Edit menu."
	einfo " "
}