cnijfilter-3.70.ebuild

cnijfilter-3.70.ebuild (text/plain), 4.09 KB, created by Tomáš Chvátal (RETIRED) on 2012-12-21 17:26:01 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit eutils autotools flag-o-matic multilib

DESCRIPTION="Canon InkJet Printer Driver for Linux (Pixus/Pixma-Series)."
HOMEPAGE="http://support-sg.canon-asia.com/contents/SG/EN/0100469302.html"
RESTRICT="nomirror confcache"
SRC_URI="http://gdlp01.c-wss.com/gds/8/0100004118/01/${PN}-source-${PV}-1.tar.gz"

LICENSE="GPL-2 Properietary"
SLOT="0"
KEYWORDS="~amd64 ~x86"
PRINTER_USE=( ip100 mx710 mx890 mx370 mx430 mx510 e600 )
PRINTER_ID=( 303 394 395 396 397 398 399 )
PRINTER_COMP=( ip100series mx710series mx890series mx370series mx430series mx510series e600series )
IUSE="${PRINTER_USE[@]} +net +servicetools"

RDEPEND="
	>=media-libs/libpng-1.5
	>=media-libs/tiff-3.4
	>=net-print/cups-1.4
	servicetools? (
		>=dev-libs/libxml2-2.7.3-r2
		>=x11-libs/gtk+-2.6:2
	)
"
DEPEND="${DEPEND}
	sys-devel/gettext
"

REQUIRED_USE="|| ( ${PRINTER_USE} )"

S="${WORKDIR}/${PN}-source-${PV}-1"

pkg_setup() {
	[[ -z ${LINGUAS} ]] && LINGUAS="en"

	DIRS="libs pstocanonij"
	use net && DIRS+=" backendnet"
	use servicetools && DIRS+=" cngpij cngpijmon"
	DIRS_PRINTER="cnijfilter"
	use servicetools && DIRS_PRINTER+=" printui"
}

src_prepare() {
	local d i

	# missing macros directory make aclocal fail
	mkdir printui/m4 || die

	epatch \
		"${FILESDIR}/${PN}"-3.70-png.patch \
		"${FILESDIR}/${PN}"-3.70-ppd.patch \
		"${FILESDIR}/${PN}"-3.70-libexec-cups.patch

	for d in ${DIRS}; do
		pushd ${d} >/dev/null
		eautoreconf
		popd > /dev/null
	done

	for d in ${DIRS_PRINTER}; do
		pushd ${d} >/dev/null
		eautoreconf
		popd > /dev/null
	done

	for (( i=0; i<${#PRINTER_USE[@]}; i++ )); do
		local name="${PRINTER_USE[$i]}"
		local pid="${PRINTER_ID[$i]}"
		if use ${name}; then
			mkdir -p ${name} || die
			ln -s ${pid} ${name} || die
			ln -s lgmon ${name} || die
			for d in ${DIRS_PRINTER}; do
				cp -a ${d} ${name} || die
			done
		fi
	done
}

src_configure() {
	local d i

	for d in ${DIRS}; do
		echo ">>> Working in: ${d}"
		pushd ${d} >/dev/null
		econf
		popd > /dev/null
	done

	for (( i=0; i<${#PRINTER_USE[@]}; i++ )); do
		local name="${PRINTER_USE[$i]}"
		if use ${name}; then
			for d in ${DIRS_PRINTER}; do
				echo ">>> Working in: ${name}/${d}"
				pushd ${name}/${d} > /dev/null
				econf \
					--program-suffix=${name}
				popd > /dev/null
			done
		fi
	done
}

src_compile() {
	local d

	for d in ${DIRS}; do
		echo ">>> Working in: ${d}"
		pushd ${d} >/dev/null
		emake
		popd > /dev/null
	done

	for (( i=0; i<${#PRINTER_USE[@]}; i++ )); do
		local name="${PRINTER_USE[$i]}"
		if use ${name}; then
			for d in ${DIRS_PRINTER}; do
				echo ">>> Working in: ${name}/${d}"
				pushd ${name}/${d} > /dev/null
				emake
				popd > /dev/null
			done
		fi
	done
}

src_install() {
	local _libdir="${EPREFIX}/usr/$(get_libdir)"
	local _libdir_pkg=libs_bin$(use amd64 && echo 64 || echo 32)
	local _ppddir="${EPREFIX}/usr/share/cups/model"

	for d in ${DIRS}; do
		echo ">>> Working in: ${d}"
		pushd ${d} >/dev/null
		emake DESTDIR=${D} install
		popd > /dev/null
	done

	if use net; then
		pushd com/${_libdir_pkg} > /dev/null
		ln -sf libcnnet.so.* libcnnet.so
		dodir ${_libdir}
		# no doexe to preserve symlinks
		cp -a libcnnet.so.* ${ED}/${_libdir} || die
		popd > /dev/null
	fi

	for (( i=0; i<${#PRINTER_USE[@]}; i++ )); do
		local name="${PRINTER_USE[$i]}"
		local pid="${PRINTER_ID[$i]}"
		if use ${name}; then
			for d in ${DIRS_PRINTER}; do
				echo ">>> Working in: ${name}/${d}"
				pushd ${name}/${d} > /dev/null
				emake DESTDIR=${D} install
				popd > /dev/null
			done
			dodir ${_libdir}
			# no doexe due to symlinks
			cp -a ${pid}/${_libdir_pkg}/* ${ED}/${_libdir} || die
			exeinto ${_libdir}/cnijlib
			doexe ${pid}/database/*
			insinto ${_ppddir}
			doins ppd/canon${name}.ppd
		fi
	done
}

pkg_postinst() {
	einfo ""
	einfo "For installing a printer:"
	einfo " * Restart CUPS: /etc/init.d/cupsd restart"
	einfo " * Go to http://127.0.0.1:631/"
	einfo "   -> Printers -> Add Printer"
	einfo ""
	einfo "If you experience any problems, please visit:"
	einfo " http://forums.gentoo.org/viewtopic-p-3217721.html"
	einfo ""
}