tvheadend-3.2 ebuild

tvheadend-3.2.ebuild (text/plain), 1.65 KB, created by BT on 2012-10-27 00:42:34 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit eutils toolchain-funcs user

DESCRIPTION="A combined DVB receiver, Digital Video Recorder and Live TV streaming server"
HOMEPAGE="https://www.lonelycoder.com/redmine/projects/tvheadend/"
SRC_URI="https://github.com/downloads/${PN}/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi xmltv zlib"

DEPEND="dev-libs/openssl
	avahi? ( net-dns/avahi )
	zlib? ( sys-libs/zlib )
	virtual/linuxtv-dvb-headers"

RDEPEND="${DEPEND}
	xmltv? ( media-tv/xmltv )"

DOCS=( README )

pkg_setup() {
	enewuser tvheadend -1 -1 /dev/null video
}

src_prepare() {
	# set the correct version number
	sed -i \
		-e "s:(3.1.694):(${PV}):" \
		debian/changelog || die "sed failed!"

	# remove '-Werror' wrt bug #438424
	sed -i 's:-Werror::' Makefile || die "sed on removing '-Werror' failed!"
}

src_configure() {
	econf \
		--prefix="${EPREFIX}"/usr \
		--datadir="${EPREFIX}"/usr/share/"${PN}" \
		--mandir="${EPREFIX}"/usr/share/man/man1 \
		--release \
		$(use_enable avahi) \
		--disable-dvbscan \
		$(use_enable zlib)
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	default

	newinitd "${FILESDIR}/tvheadend.initd" tvheadend
	newconfd "${FILESDIR}/tvheadend.confd" tvheadend

	dodir /etc/tvheadend
	fperms 0700 /etc/tvheadend
	fowners tvheadend:video /etc/tvheadend
}

pkg_postinst() {
	elog "The Tvheadend web interface can be reached at:"
	elog "http://localhost:9981/"
	elog
	elog "Make sure that you change the default username"
	elog "and password via the Configuration / Access control"
	elog "tab in the web interface."
}