kgio-2.7.4.ebuild

kgio-2.7.4.ebuild (text/plain), 940 bytes, created by Coacher on 2012-10-23 01:03:44 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
USE_RUBY="ruby18 ruby19"

RUBY_FAKEGEM_RECIPE_DOC="rdoc"
RUBY_FAKEGEM_DOC_SOURCES="lib ext/${PN}/*.c"
RUBY_FAKEGEM_EXTRADOC="README TODO NEWS ChangeLog ISSUES HACKING"

RUBY_FAKEGEM_TASK_TEST="none"

inherit ruby-fakegem

DESCRIPTION="kgio provides non-blocking I/O methods for Ruby"
HOMEPAGE="http://bogomips.org/kgio/"

LICENSE="|| ( LGPL-2.1 LGPL-3.0 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

each_ruby_configure() {
	${RUBY} -C ext/${PN} extconf.rb || die
}

each_ruby_compile() {
	emake -C ext/${PN} || die
	cp "ext/${PN}/${PN}_ext.so" lib/ || die
}

each_ruby_test() {
	# we have to do tests manually as there is no rake task for this
	# only make target which does exactly the same plus one extra build of
	# everything
	for tu in test/test_*.rb; do
		${RUBY} -Ilib $tu || die "test $tu failed"
	done
}