tvheadend-3.0 ebuild

tvheadend-3.0.ebuild (text/plain), 1.62 KB, created by Sergey Popov on 2012-10-16 08:29:00 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit eutils toolchain-funcs user vcs-snapshot

DESCRIPTION="A combined DVB receiver, Digital Video Recorder and Live TV streaming server"
HOMEPAGE="https://www.lonelycoder.com/redmine/projects/tvheadend/"
SRC_URI="https://github.com/${PN}/${PN}/tarball/${PV} -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi xmltv"

DEPEND="dev-libs/openssl
	sys-libs/zlib
	virtual/linuxtv-dvb-headers
	avahi? ( net-dns/avahi )"

RDEPEND="${DEPEND}
	xmltv? ( media-tv/xmltv )"

DOCS=( README )

pkg_setup() {
	enewuser tvheadend -1 -1 /dev/null video
}

src_prepare() {
	# set version number to avoid git dependency
	sed -i \
		-e 's:revision=`$1/support/getver.sh`:revision=${PV}:' \
		support/version.sh || die "sed failed!"

	sed -i 's:-Werror::' Makefile || die "sed failed!"
}

src_configure() {
	econf \
		--prefix="${EPREFIX}"/usr \
		--datadir="${EPREFIX}"/usr/share/"${PN}" \
		--mandir="${EPREFIX}"/usr/share/man/man1 \
		--enable-zlib \
		--release \
		$(use_enable avahi)
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	default

	newinitd "${FILESDIR}/tvheadend.initd" tvheadend
	newconfd "${FILESDIR}/tvheadend.confd" tvheadend

	dodir /etc/tvheadend
	fperms 0700 /etc/tvheadend
	fowners tvheadend:video /etc/tvheadend
}

pkg_postinst() {
	elog "The Tvheadend web interface can be reached at:"
	elog "http://localhost:9981/"
	elog
	elog "Make sure that you change the default username"
	elog "and password via the Configuration / Access control"
	elog "tab in the web interface."
}