vips-7.30.1.ebuild

vips-7.30.1.ebuild (text/plain), 2.19 KB, created by Steven Peckins on 2012-08-31 19:40:58 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3
PYTHON_DEPEND="python? 2"
inherit eutils versionator python

# Version bump to 7.30 (#412447)
# Add matio (#269598) USE flags
# Remove liboil dependency (#416815)
# Add cxx (#416817) and v4l USE flags
# Update HOMEPAGE to VIPS wiki (since sourceforge redirects there anyway)
# Remove README from docs list (because it doesn't exist in this release)

DESCRIPTION="VIPS Image Processing Library"
SRC_URI="http://www.vips.ecs.soton.ac.uk/supported/$(get_version_component_range 1-2)/${P}.tar.gz"
HOMEPAGE="http://www.vips.ecs.soton.ac.uk/index.php?title=VIPS"

RESTRICT="mirror"
LICENSE="LGPL-2.1"
SLOT="1"
KEYWORDS="~amd64 ~x86"
IUSE="cxx debug exif fits fftw imagemagick jpeg lcms matio openexr
	+orc png python static-libs tiff v4l"

RDEPEND=">=dev-libs/glib-2.6:2
	dev-libs/libxml2
	sys-libs/zlib
	>=x11-libs/pango-1.8
	fftw? ( sci-libs/fftw:3.0 )
	imagemagick? ( || ( >=media-gfx/imagemagick-5.0.0
		media-gfx/graphicsmagick[imagemagick] ) )
	lcms? ( media-libs/lcms )
	matio? ( >=sci-libs/matio-1.3.4 )
	openexr? ( >=media-libs/openexr-1.2.2 )
	exif? ( >=media-libs/libexif-0.6 )
	tiff? ( media-libs/tiff )
	jpeg? ( virtual/jpeg )
	fits? ( sci-libs/cfitsio )
	png? ( >=media-libs/libpng-1.2.9 )
	orc? ( >=dev-lang/orc-0.4.11 )"
DEPEND="${RDEPEND}
	dev-util/gtk-doc-am"

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_configure() {
	econf \
		$(use_enable debug) \
		$(use_enable cxx) \
		$(use_with fftw) \
		$(use_with lcms) \
		$(use_with openexr OpenEXR) \
		$(use_with matio ) \
		$(use_with exif libexif) \
		$(use_with imagemagick magick) \
		$(use_with png) \
		$(use_with tiff) \
		$(use_with fits cfitsio) \
		$(use_with jpeg) \
		$(use_with orc) \
		$(use_with python) \
		$(use_with v4l) \
		$(use_enable static-libs static)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS THANKS TODO || die

	# 314101
	mv "${ED}"/usr/share/doc/${PN}/* "${ED}"/usr/share/doc/${PF} || die
	rmdir "${ED}"/usr/share/doc/${PN}/ || die
	dosym /usr/share/doc/${PF} /usr/share/doc/${PN}

	find "${ED}" -name '*.la' -exec rm -f {} +
}