stone-soup-0.10.3.ebuild

stone-soup-0.10.3.ebuild (text/plain), 2.78 KB, created by Julian Ospald on 2012-08-28 09:33:20 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

## TODO
# add sound support (no build switch, no sound files)

EAPI=4
VIRTUALX_REQUIRED="manual"
inherit eutils gnome2-utils virtualx games

MY_P="stone_soup-${PV}"
DESCRIPTION="Role-playing roguelike game of exploration and treasure-hunting in dungeons"
HOMEPAGE="http://crawl.develz.org/wordpress/"
SRC_URI="mirror://sourceforge/crawl-ref/Stone%20Soup/${PV}/${MY_P}-nodeps.tar.xz
	http://dev.gentoo.org/~hasufell/distfiles/${PN}.png
	http://dev.gentoo.org/~hasufell/distfiles/${PN}.svg"

# 3-clause BSD: mt19937ar.cc, MSVC/stdint.h
# 2-clause BSD: all contributions by Steve Noonan and Jesse Luehrs
# Public Domain|CC0: most of tiles
# MIT: json.cc/json.h, some .js files in webserver/static/scripts/contrib/
LICENSE="GPL-2 BSD BSD-2 public-domain CC0-1.0-Universal MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug +lua +tiles"
# test might fail
# see https://crawl.develz.org/mantis/view.php?id=6121
RESTRICT="!debug? ( test )"

RDEPEND="
	dev-db/sqlite:3
	sys-libs/zlib
	tiles? (
		media-libs/freetype:2
		media-libs/libpng:0
		media-libs/libsdl[X,opengl,video]
		media-libs/sdl-image[png]
		)
	!tiles? ( sys-libs/ncurses )
	lua? ( >=dev-lang/lua-5.1.0 )"
DEPEND="${RDEPEND}
	dev-lang/perl
	|| ( sys-devel/bison dev-util/byacc dev-util/yacc )
	sys-devel/flex
	tiles? (
		sys-libs/ncurses
		virtual/pkgconfig
		test? ( ${VIRTUALX_DEPEND} )
		)"

S=${WORKDIR}/${MY_P}/source
S_TEST=${WORKDIR}/${MY_P}_test/source

src_prepare() {
	epatch "${FILESDIR}"/${P}-build.patch

	if use test ; then
		cp -av "${WORKDIR}/${MY_P}" "${WORKDIR}/${MY_P}_test" \
			|| die "setting up test-dir failed"
	fi
}

src_configure() {
	# leave DATADIR at the top
	myemakeargs=(
		DATADIR="${GAMES_DATADIR}/${PN}"
		V=1
		prefix="${GAMES_PREFIX}"
		SAVEDIR="~/.crawl"
		$(usex debug "FULLDEBUG=y DEBUG=y" "")
		$(usex lua "" "NO_LUA_BINDINGS=y")
		$(usex tiles "TILES=y" "")
	)
}

src_compile() {
	emake ${myemakeargs[@]}

	# for test to work we need to compile with unset DATADIR
	if use test ; then
		emake ${myemakeargs[@]:1} -C "${S_TEST}"
	fi
}

src_install() {
	emake ${myemakeargs[@]} DESTDIR="${D}" install

	# don't relocate docs, needed at runtime
	rm -rf "${D}${GAMES_DATADIR}"/${PN}/docs/license
	dodoc "${WORKDIR}"/${MY_P}/README.{txt,pdf}

	# icons and menu for graphical build
	if use tiles ; then
		doicon -s 48 "${DISTDIR}"/${PN}.png
		doicon -s scalable "${DISTDIR}"/${PN}.svg
		make_desktop_entry crawl
	fi

	prepgamesdirs
}

src_test() {
	cd "${S_TEST}" || die
	if use tiles; then
		Xemake ${myemakeargs[@]:1} test
	else
		emake ${myemakeargs[@]:1} test
	fi
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}