Epson Perfection V200 scanner plugin for 'epkowa' backend

iscan-plugin-gt-f670-2.1.2.1.ebuild (text/plain), 2.47 KB, created by Stefan Borschtel on 2012-08-22 12:13:45 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/iscan-plugin-esdip/iscan-plugin-esdip-1.0.0.5.ebuild,v 1.1 2012/06/04 23:12:39 flameeyes Exp $

EAPI=4

inherit rpm versionator multilib

MY_PV="$(get_version_component_range 1-3)"
MY_PVR="$(replace_version_separator 3 -)"

DESCRIPTION="Epson Perfection V200 scanner plugin for 'epkowa' backend."
HOMEPAGE="http://www.avasys.jp/english/linux_e/dl_scan.html"
SRC_URI="
	x86? ( http://linux.avasys.jp/drivers/iscan-plugins/${PN}/${MY_PV}/${PN}-${MY_PVR}.i386.rpm )
	amd64? ( http://linux.avasys.jp/drivers/iscan-plugins/${PN}/${MY_PV}/${PN}-${MY_PVR}.x86_64.rpm )
"

LICENSE="AVASYS"
SLOT="0"
KEYWORDS="-* ~amd64"

IUSE=""

DEPEND=">=media-gfx/iscan-2.28.0"

RDEPEND="${DEPEND}"

S="${WORKDIR}"


QA_PREBUILT="
    /opt/iscan/esci/libesint7A.so.2.0.1
    /opt/iscan/esci/libesint7A.so.2
    /opt/iscan/esci/libesint7A.so"

src_configure() { :; }
src_compile() { :; }

src_install() {
    # install scanner firmware
    insinto /usr/share/iscan
    doins "${WORKDIR}/usr/share/iscan/"*

    dodoc usr/share/doc/*/*

    # install scanner plugins
    exeinto /opt/iscan/esci
    doexe "${WORKDIR}/usr/$(get_libdir)/iscan/"*
}

pkg_setup() {
    basecmds=(
        "iscan-registry --COMMAND interpreter usb 0x04b8 0x012e /opt/iscan/esci/libesint7A /usr/share/iscan/esfw7A.bin"
    )
}

pkg_postinst() {
    elog
    elog "Firmware file esfw7a.bin for Epson Perfection V200"
    elog "has been installed in /usr/share/iscan."
    elog

    [[ -n ${REPLACING_VERSIONS} ]] && return

    # Needed for scanner to work properly.
    if [[ ${ROOT} == "/" ]]; then
        for basecmd in "${basecmds[@]}"; do
            eval ${basecmd/COMMAND/add}
        done
    else
        ewarn "Unable to register the plugin and firmware when installing outside of /."
        ewarn "execute the following command yourself:"
        for basecmd in "${basecmds[@]}"; do
            ewarn "${basecmd/COMMAND/add}"
        done
    fi
}

pkg_prerm() {
    [[ -n ${REPLACED_BY_VERSION} ]] && return

    if [[ ${ROOT} == "/" ]]; then
        for basecmd in "${basecmds[@]}"; do
            eval ${basecmd/COMMAND/remove}
        done
    else
        ewarn "Unable to de-register the plugin and firmware when installing outside of /."
        ewarn "execute the following command yourself:"
        for basecmd in "${basecmds[@]}"; do
            ewarn "${basecmd/COMMAND/remove}"
        done
    fi
}