new ebuild media-sound/gwc/gwc-0.16.ebuild

gwc-0.16.ebuild (text/plain), 1.52 KB, created by Paul Thompson on 2002-08-16 19:57:39 UTC

# Copyright 2002 Paul Thompson
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="Gnome Wave Cleaner: Designed to denoise/depop sound recordings"

HOMEPAGE="http://www2.redhawk.org/"

SRC_URI="http://www2.redhawk.org/download/${P}.tgz"

LICENSE="GPL-1"
SLOT="0"
KEYWORDS="x86"

# some of these dependancies may be redundant
DEPEND=">=dev-libs/glib-1.2.10-r4
		>=gnome-base/gnome-libs-1.4.1.7
		>=media-libs/audiofile-0.2.3-r1
		>=media-libs/imlib-1.9.14-r1
		>=media-sound/esound-0.2.28-r1
		>=sys-libs/db-1.85-r1
		>=sys-libs/zlib-1.1.4
		>=x11-base/xfree-4.2.0-r12
		>=x11-libs/gtk+-1.2.10-r8"

RDEPEND="${DEPEND}"

S="${WORKDIR}/${P}"

src_compile() {
	# These things want to auto-configure your CFLAGS. I hope they
	# dont know better than you! :)
	cp Makefile.in Makefile.in.orig
	sed -e "/^CFLAGS =/s/-mcpu=@UNAME_MACHINE@ -march=@UNAME_MACHINE@//" \
		-e "/^CFLAGS =/s/-O3/${CFLAGS}/" < Makefile.in.orig > Makefile.in
	econf || die "configure failed"

	# For some reason, I have to go in, configure and build this library first,
	# or it misdetects things, and wont link in the end.
	cd meschach 
		cp makefile.in makefile.in.orig
		sed -e "/^CFLAGS =/s/-O3/${CFLAGS}/" < makefile.in.orig > makefile.in
		PATH=".:$PATH"
		econf --with-sparse || die "failed to configure meschach lib"
		( make part1 ; make part2 ; make part3 ) || die \
			"failed to compile meschach math lib"
	cd ..

	emake || die
}

src_install () {
	into /usr
	dobin gwc

	dodoc TODO COPYING README Changelog
	dohtml gwc_help.html
}