pithos-9999.ebuild

pithos-9999.ebuild (text/plain), 1.20 KB, created by Nathan Caldwell on 2012-06-03 01:37:43 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="3"
PYTHON_DEPEND="2:2.6"
SUPPORT_PYTHON_ABIS="1"
VIRTUALX_REQUIRED="always"
inherit git-2 distutils virtualx

EGIT_REPO_URI="git://github.com/kevinmehall/pithos.git
				https://github.com/kevinmehall/pithos.git"
DESCRIPTION="A Pandora Radio (pandora.com) player for the GNOME Desktop"
HOMEPAGE="http://kevinmehall.net/p/pithos/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""
IUSE="gnome"

DEPEND="dev-python/python-distutils-extra"

RDEPEND="dev-python/pyxdg
	dev-python/pygobject:2
	dev-python/notify-python
	dev-python/pygtk
	dev-python/gst-python
	dev-python/dbus-python
	media-plugins/gst-plugins-meta[aac,http,mp3]
	gnome? ( gnome-base/gnome-settings-daemon )
	!gnome? ( dev-libs/keybinder[python] )"

RESTRICT_PYTHON_ABIS="2.[45] 3.*"
DISTUTILS_USE_SEPARATE_SOURCE_DIRECTORIES="1"

src_prepare() {
	distutils_src_prepare

	# bug #216009
	# avoid writing to /root/.gstreamer-0.10/registry.xml
	export GST_REGISTRY="${T}"/registry.xml
}

src_compile() {
	VIRTUALX_COMMAND="distutils_src_compile" virtualmake
}

src_install() {
	VIRTUALX_COMMAND="distutils_src_install" virtualmake --prefix="${EPREFIX}/usr"
}