gtk2hs-0.9.5.ebuild

gtk2hs-0.9.5.ebuild (text/plain), 2.28 KB, created by Duncan Coutts (RETIRED) on 2004-05-13 19:35:41 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="GTK+-2.x bindings for Haskell"
HOMEPAGE="http://gtk2hs.sourceforge.net/"
SRC_URI="mirror://sourceforge/gtk2hs/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"

KEYWORDS="~x86"

IUSE="opengl glade gnome"

RDEPEND=">=virtual/ghc-6.2
		>=x11-libs/gtk+-2
		glade? ( >=gnome-base/libglade-2 )
		gnome? ( >=x11-libs/gtksourceview-0.6 )
		opengl? ( virtual/opengl
        	      virtual/glu
            	  virtual/glut 
				  x11-libs/gtkglext )"

DEPEND="${RDEPEND}"

# the variable ghc_version is used to store the ghc version we are building against

src_compile() {
	# determine ghc library directory
	# (so that it's possible to install the library for
	# multiple versions of ghc)
	local myopts
	ghc_version=`best_version virtual/ghc | sed "s:.*/::"`
	test -n ${ghc_version} && ghclibdir="/usr/lib/${ghc_version}"
	test -n ${ghclibdir} || ghclibdir="/usr/lib"
	test -n ${ghclibdir} && myopts="${myopts} --libdir=${D}${ghclibdir}"

	# configure, override hc flags to not specify heap size
	econf --with-hcflags="-O" \
		`use_enable gnome sourceview` \
		`use_enable glade libglade` \
		`use_enable opengl glext` \
		${myopts} \
		|| die "Configure failed"
	
	# parallell build doesn't work, so specify -j1
	emake -j1 || die "Make failed"
	
	# create documentation
	#if [ `use doc` ]; then
	#	make doc || die "Make doc failed"
	#fi
}

src_install() {

	make install-without-pkg || die "Make install failed"

	# Correct the package config files
	sed -i "s:${D}::g" ${D}/${ghclibdir}/*.conf

	#if [ `use doc` ]; then
	#	dohtml -A haddock -r out/doc/*
	#	cp -r samples ${D}/usr/share/doc/${PF}
	#fi
}

pkg_postinst() {
	register_ghc_packages
}

register_ghc_packages() {
	einfo "Registering gtk2hs packages"
	ghc-pkg -u -i ${ghclibdir}/gtk2.conf
	ghc-pkg -u -i ${ghclibdir}/mogul.conf
	use gnome && ghc-pkg -u -i ${ghclibdir}/sourceview.conf
	use glade && ghc-pkg -u -i ${ghclibdir}/glade2hs.conf
}

pkg_prerm() {
	# check if another version is still there
	has_version "<${CATEGORY}/${PF}" \
		|| has_version ">${CATEGORY}/${PF}" \
		|| unregister_ghc_packages
}

unregister_ghc_packages() {
	einfo "Unregistering gtk2hs packages"
	ghc-pkg -r gtk2
	ghc-pkg -r mogul
	ghc-pkg -r glade2hs
	ghc-pkg -r sourceview
}