fixed ebuild from progress overlay

gevent-0.13.7.ebuild (text/plain), 1.39 KB, created by Morozov Alexandr on 2012-05-13 21:44:29 UTC

# Copyright owners: Arfrever Frehtes Taifersar Arahesis
# Distributed under the terms of the GNU General Public License v2

EAPI=4
PYTHON_DEPEND="*:2.5"
SUPPORT_PYTHON_ABIS="1"

inherit distutils python

DESCRIPTION="Python networking library based on greenlet and libevent"
HOMEPAGE="http://www.gevent.org/ http://code.google.com/p/gevent/ http://pypi.python.org/pypi/gevent"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="BSD MIT"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="doc examples test"

RDEPEND="dev-libs/libevent
	     dev-python/greenlet"
DEPEND="${RDEPEND}
	dev-python/setuptools
	doc? ( dev-python/sphinx )
	test? ( dev-python/pysqlite )"

RESTRICT_PYTHON_ABIS="3.*"

PYTHON_CFLAGS=("2.* + -fno-strict-aliasing")

DOCS="AUTHORS changelog.rst"

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Generation of documentation"
		pushd doc > /dev/null
		PYTHONPATH="$(ls -d ../build-$(PYTHON -f --ABI)/lib.*)" emake html
		popd > /dev/null
	fi
}

src_test() {
	cd greentest

	testing() {
		python_execute PYTHONPATH="$(ls -d ../build-${PYTHON_ABI}/lib.*)" "$(PYTHON)" testrunner.py
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	if use doc; then
		pushd doc/_build/html > /dev/null
		insinto /usr/share/doc/${PF}/html
		doins -r [a-z]* _static
		popd > /dev/null
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins -r examples/*
	fi
}