xboard-4.6.0.ebuild

xboard-4.6.0.ebuild (text/plain), 1.61 KB, created by Julian Ospald on 2012-03-13 16:44:11 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3

inherit games fdo-mime gnome2-utils

DESCRIPTION="GUI for gnuchess and for internet chess servers"
HOMEPAGE="http://www.gnu.org/software/xboard/"
SRC_URI="mirror://gnu/xboard/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="+default-font engine Xaw3d zippy"

RDEPEND="x11-libs/libXaw
	default-font? ( media-fonts/font-adobe-100dpi )
	engine? ( || (
		games-board/crafty
		games-board/gnuchess
		games-board/fruit
		games-board/phalanx
		games-board/sjeng
	) )
	Xaw3d? ( x11-libs/libXaw3d )"
DEPEND="${RDEPEND}"

src_configure() {
	egamesconf \
		--disable-dependency-tracking \
		--datadir=/usr/share \
		$(use_with Xaw3d) \
		$(use_enable zippy)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS COPYRIGHT ChangeLog NEWS README TODO ics-parsing.txt || die
	if use zippy ; then
		dodoc zippy.README || die
	fi
	dohtml FAQ.html || die

	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst

	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update

	gnome2_icon_cache_update

	elog "No chess engines are emerged by default! If you want a chess engine"
	elog "to play with, you can emerge gnuchess or crafty."
	elog "Read xboard FAQ for information."
	if ! use default-font ; then
		ewarn "Read the xboard(6) man page for specifying the font for xboard to use."
	fi
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update

	gnome2_icon_cache_update
}