freewnn-1.1.1_alpha17.ebuild

freewnn-1.1.1_alpha17.ebuild (text/plain), 1.40 KB, created by MATSUU Takuto (RETIRED) on 2004-05-01 23:57:43 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/app-i18n/freewnn/freewnn-1.1.1_alpha20.ebuild,v 1.6 2004/03/13 20:44:55 dholm Exp $

MY_P="FreeWnn-${PV/_alpha/-a0}"

DESCRIPTION="Network-Extensible Kana-to-Kanji Conversion System"
HOMEPAGE="http://www.freewnn.org/"
SRC_URI="ftp://ftp.freewnn.org/pub/FreeWnn/alpha/${MY_P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86 ~sparc ~alpha ~ia64 ~amd64 ~ppc"
IUSE="X ipv6"

DEPEND="virtual/glibc
	X? ( virtual/x11 )"

S="${WORKDIR}/${MY_P}/Xsi"

src_unpack() {
	unpack ${A}

	# from FreeWnn-1.11-42.1.src.rpm(Fedora Core 1)
	epatch ${FILESDIR}/FreeWnn-1.1.1-fix-x86-64-61907.patch
	epatch ${FILESDIR}/FreeWnn-ia64.patch

	#Change WNNOWNER to root so we don't need to add wnn user
	sed -i -e "s/WNNOWNER = wnn/WNNOWNER = root/" ${S}/makerule.mk.in
}

src_compile() {
	econf \
		--disable-cWnn \
		--disable-kWnn \
		--without-termcap \
		`use_with X x` \
		`use_with ipv6` || die "./configure failed"

	emake || die
	#make || die
}

src_install () {
	# install executables, libs ,dictionaries
	make DESTDIR=${D} install || die "installation failed"
	# install man pages
	make DESTDIR=${D} install.man || die "installation of manpages failed"
	# install docs
	dodoc ChangeLog* INSTALL* CONTRIBUTORS
	# install rc script
	exeinto /etc/init.d ; newexe ${FILESDIR}/freewnn.initd freewnn
}