d2x-full-0.2.5.ebuild (New Package)

d2x-full-0.2.5.ebuild (text/plain), 2.14 KB, created by David A Bestor on 2004-04-30 05:12:56 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit flag-o-matic eutils games

DESCRIPTION="Descent 2 Full Version"
HOMEPAGE="http://icculus.org/d2x/"
SRC_URI="http://icculus.org/d2x/src/d2x-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ppc"
IUSE="debug opengl ggi svga"

RDEPEND="media-libs/libsdl
    app-arch/unarj
	media-libs/sdl-image
	opengl? ( virtual/opengl )
	ggi? ( media-libs/libggi )
	svga? ( media-libs/svgalib )"
DEPEND="${RDEPEND}
	x86? ( dev-lang/nasm )"

S=${WORKDIR}/d2x-${PV}
	
pkg_setup() {
        cdrom_get_cds d2data
        if [ -e ${CDROM_ROOT}/d2data/descent2.sow ] ; then
                export CDROM_ROOT=${CDROM_ROOT}/d2data
                einfo "Found the original Descent2 CD"
        else
                die "You need the original Descent2 CD"
        fi

        games_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd ${WORKDIR}
	mkdir SOW
	cd SOW
	unarj e ${CDROM_ROOT}/descent2.sow
	rm *.{exe,bat}
	cd ${S}
	epatch ${FILESDIR}/${PV}-shellscripts.patch
}

src_compile() {
	# --disable-network --enable-console
	local myconf="`use_enable x86 assembler`"
	use debug \
		&& debugconf="${myconf} --enable-debug --disable-release" \
		|| debugconf="${myconf} --disable-debug --enable-release"
	# we do this because each of the optional guys define the same functions
	# in gr, thus when they go to link they cause redefine errors ...
	# we build each by it self, save the binary file, clean up, and start over
	mkdir my-bins
	for ren in sdl `use opengl` `use svga` `use ggi` ; do
		[ "${ren}" == "sdl" ] \
			&& renconf="" \
			|| renconf="--with-${ren}"
		[ "${ren}" == "svga" ] \
			&& defflags="-DSVGALIB_INPUT" \
			|| defflags=""
		make distclean
		egamesconf \
			${myconf} \
			${renconf} \
			--datadir=${GAMES_DATADIR_BASE} \
			|| die "conf ${ren}"
		emake CXXFLAGS="${CXXFLAGS} ${defflags}" || die "build ${ren}"
		mv d2x* my-bins/
	done
}

src_install() {
	make install DESTDIR=${D} || die
	dogamesbin my-bins/*
	dodir ${GAMES_DATADIR}/d2x
	cp -r ${WORKDIR}/SOW/* ${D}/${GAMES_DATADIR}/d2x/
	dodoc AUTHORS ChangeLog NEWS README* TODO readme.txt
	prepgamesdirs
}