Improved ebuild

openttd-0.3.1.ebuild (text/plain), 1.81 KB, created by Hinrik Örn Sigurðsson on 2004-04-27 07:57:14 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="OpenTTD is a clone of Transport Tycoon Deluxe"
HOMEPAGE="http://www.openttd.com/"
SRC_URI="mirror://sourceforge/openttd/${P}.tgz"
LICENSE="GPL-2"

SLOT="0"

KEYWORDS="~x86 ~ppc"
IUSE="debug png zlib"

DEPEND="virtual/glibc
		virtual/x11
		media-sound/timidity++
		media-sound/timidity-eawpatches
		png? ( media-libs/libpng )
		zlib? ( sys-libs/zlib )"

src_unpack() {

	# revamped Makefile
	unpack ${P}.tgz
	cp ${FILESDIR}/${P}-new-Makefile ${S}/Makefile
	cd ${S}
	epatch ${FILESDIR}/${P}-homedir_settings.patch
}

src_compile() {
	
	local myopts
	use debug && myopts="${myopts} DEBUG=1"
	use png && myopts="${myopts} WITH_PNG=1"
	use zlib && myopts="${myopts} WITH_ZLIB=1"
	emake ${myopts} -j1 || die "emake failed"

	# make the extra languages
	./strgen/strgen lang/french.txt
	./strgen/strgen lang/german.txt
	./strgen/strgen lang/italian.txt
	./strgen/strgen lang/swedish.txt
}

src_install() {

	# installing this version into /opt for now because of
	# how OpenTTD looks for its datafiles

	local dir=${GAMES_PREFIX_OPT}/${PN}

	exeinto ${dir}
	doexe ttd
	games_make_wrapper openttd "./ttd -m extmidi" ${dir}

	insinto ${dir}/data
	doins data/*
	insinto ${dir}/lang
	doins lang/*.lng

	insinto /usr/share/pixmaps
	newins media/icon128.png openttd.png
	make_desktop_entry openttd "OpenTTD" openttd.png

	dodoc readme.txt changelog.txt
}

pkg_postinst() {
	games_pkg_postinst

	einfo "In order to play, you must copy the following 5 files from "
	einfo "the *WINDOWS* version of TTD to /opt/openttd/data/"
	einfo ""
	einfo "sample.cat trg1r.grf trgcr.grf trghr.grf trgir.grf trgtr.grf"
	einfo ""
	einfo "If you want music, you must copy the gm/ directory"
	einfo "to /opt/openttd/"
	einfo ""
}