ooofbtools-1.26.ebuild

ooofbtools-1.26.ebuild (text/plain), 1.60 KB, created by M8R-u38wij on 2012-01-08 19:35:15 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit multilib

MY_PN="OOoFBTools"

DESCRIPTION="The FictionBook's Tools extension for [Open|Libre]Office.org"
HOMEPAGE="http://www.fbtools.org/"
SRC_URI="http://ooofbtools.googlecode.com/files/${MY_PN}-${PV}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="doc examples"
RESTRICT="mirror strip"

DEPEND="virtual/ooo"
RDEPEND=${DEPEND}

S=${WORKDIR}/${MY_PN}-${PV}

EXT_D=""

get_implementation() {
	debug-print-function ${FUNCNAME} "$@"
	local implementations=(
		"libreoffice"
		"openoffice"
	)
	local i

	for i in "${implementations[@]}"; do
		if [[ -d "${EPREFIX}/usr/$(get_libdir)/${i}" ]]; then
			debug-print "${FUNCNAME}: Determined implementation is: \"${EPREFIX}/usr/$(get_libdir)/${i}\""
			EXT_D="usr/$(get_libdir)/${i}/share/extensions"
			return
		fi
	done

	die "Unable to determine libreoffice/openoffice implementation!"
}

src_install() {
	get_implementation
	dodir "/${EXT_D}/${MY_PN}"
	unzip "${MY_PN}.oxt" -d "${D}${EXT_D}/${MY_PN}"

	insinto "/${EXT_D}/${MY_PN}"
	doins "${FILESDIR}/Paths.xcu"
	insinto "/${EXT_D}/${MY_PN}/META-INF"
	doins "${FILESDIR}/manifest.xml"
	insinto "/${EXT_D}/${MY_PN}/template"
	doins "${FILESDIR}/groupuinames.xml"

	insinto "/${EXT_D}/${MY_PN}/template/styles"
	doins "fb21_styles.ott"

	dodoc ChangeLog_Eng.txt ChangeLog_Rus.txt
	if use doc; then
		dodoc OOoFBTools_Help.pdf
	fi
	if use examples; then
		docinto "examples"
		docompress -x "/usr/share/doc/${PF}/examples"
		dodoc ExportToFB21_example-1.odt ExportToFB21_example-2.odt
	fi
}