pymacs-0.24_beta2.ebuild

pymacs-0.24_beta2.ebuild (text/plain), 1.37 KB, created by Ulrich Müller on 2011-10-05 21:05:27 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emacs/pymacs/pymacs-0.23-r1.ebuild,v 1.9 2011/01/13 17:54:39 xarthisius Exp $

EAPI=3
PYTHON_DEPEND="2 3"
SUPPORT_PYTHON_ABIS=1

inherit distutils elisp

DESCRIPTION="A tool that allows both-side communication beetween Python and Emacs Lisp"
HOMEPAGE="http://pymacs.progiciels-bpi.ca/"
# taken from http://pymacs.progiciels-bpi.ca/archives/${MY_P}.tar.gz
SRC_URI="mirror://gentoo/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 arm hppa ia64 ppc ppc64 s390 sh x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="doc"

# additional doc? dependencies for multirow.sty and aeguill.sty (bug 247703)
DEPEND="
	doc? ( dev-python/docutils
		virtual/latex-base
		|| ( ( dev-texlive/texlive-latexextra
				dev-texlive/texlive-langfrench )
			app-text/ptex ) )"
RDEPEND=""

SITEFILE="50${PN}-gentoo.el"

src_unpack() {
	unpack ${A}
	mv pinard-Pymacs-* "${S}" || die
}

src_compile() {
	emake || die "emake failed"
	elisp-compile pymacs.el || die "elisp-compile failed"
	if use doc; then
		VARTEXFONTS="${T}"/fonts \
			emake pymacs.pdf || die "emake pymacs.pdf failed"
	fi
}

src_install() {
	elisp_src_install
	distutils_src_install
	dodoc THANKS pymacs.rst
	if use doc; then
		insinto /usr/share/doc/${PF}
		doins pymacs.pdf
	fi
}