path64-suite-9999.ebuild

path64-suite-9999.ebuild (text/plain), 4.74 KB, created by DaggyStyle on 2011-07-10 20:20:12 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
CMAKE_VERBOSE=1

if [ "${PV%9999}" != "${PV}" ] ; then
	SCM=git-2
	EGIT_REPO_URI="git://github.com/pathscale/path64-suite.git"
	EGIT_REPO_URI_LIST="git://github.com/path64/compiler.git git://github.com/pathscale/compiler-rt.git git://github.com/path64/assembler.git git://github.com/pathscale/libcxxrt.git git://github.com/pathscale/libdwarf-bsd.git git://github.com/pathscale/libunwind.git git://github.com/pathscale/stdcxx.git git://github.com/path64/debugger.git"
fi

inherit cmake-utils ${SCM} multilib toolchain-funcs

DESCRIPTION="PathScale Path64 Compiler Suite"
HOMEPAGE="http://www.path64.org/pathscale/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+assembler custom-flags debugger fortran +mathlibs +native +openmp pathopt2 +profiling valgrind"

DEPEND="!native? ( sys-devel/gcc:4.2[vanilla] )
	native? ( || ( dev-lang/ekopath-bin sys-devel/path64-suite )
		sys-libs/glibc
	)
	valgrind? ( dev-util/valgrind ) "

RDEPEND="${DEPEND}"

pkg_setup() {
	export COMPILER_PATH=""
	if use native; then
		export CMAKE_BUILD_TYPE="Release"
                export DISABLE_GENTOO_RULE_OVERRIDE="TRUE"
                if has_version sys-devel/path64-suite; then
                        COMPILER_NAME="path64"
                        export COMPILER_PATH="/usr/bin"
                else
                        COMPILER_NAME="ekopath-bin"
                        export COMPILER_PATH=$(cat /etc/env.d/99ekopath-bin | egrep "^PATH" | sed 's/=/ /g' | awk '{print $2}')
                fi

	else
		[[ $(gcc-version) != 4.2 ]] && \
			die "To bootstrap Path64 you'll need to use gcc:4.2[vanilla]"
		export COMPILER_PATH=$($(tc-getCC) -print-search-dirs | head -n 1 | cut -f2- -d' ')
	        export CMAKE_BUILD_TYPE="Debug"
                COMPILER_NAME="gcc"
        fi
        elog "using ${COMPILER_NAME} compiler, building ${CMAKE_BUILD_TYPE} mode"
}

src_unpack() {
	cd "${WORKDIR}"
	elog "checking out the suite..."
	declare -a headers=($(echo ${EGIT_REPO_URI} | sed 's/[\/\.]/ /'g) )
	local index=$((${#headers[@]} - 2))
	export EGIT_PROJECT="${headers[$index]}"
	git-2_src_unpack
	mkdir ${P}/src
	elog "checking out modules..."
	for repo in $(echo ${EGIT_REPO_URI_LIST}); do
		unset EGIT_DIR
		export EGIT_REPO_URI="${repo}"
		declare -a headers=($(echo ${EGIT_REPO_URI} | sed 's/[\/\.]/ /'g) )
		index=$((${#headers[@]} - 2))
		export EGIT_SOURCEDIR="${S}/src/${headers[$index]}"
		export EGIT_PROJECT="${PN}-${headers[$index]}"
		cd "${WORKDIR}/${P}/src"
		git-2_src_unpack
	done
	cd ${S}
	sed -i  's/\/compiler\//\/src\//g' CMakeLists.txt
	mv src/debugger src/pathdb
}

src_prepare() {
	if ! use native; then
		epatch "${FILESDIR}"/${PN}-fixlinks.patch \
		       "${FILESDIR}"/${PN}-implicits.patch
	fi
}

src_configure() {
	local MY_CFLAGS=""
	local MY_CXXFLAGS=""
	local FORTRAN_COMPILER=""
	local C_COMPILER=""
	local CXX_COMPILER=""
	local BUILD_ARCH="x86"
	local DEBUGGER_STATE=OFF
	local FORTRAN_STATE=OFF
	local OPENMP_STATE=OFF
	local MATHLIBS_STATE=OFF
	local PROFILING_STATE=OFF
	local PATHOPT2_STATE=OFF
	local VALGRIND_STATE=OFF
	
	if use custom-flags; then
		MY_CFLAGS=$"{CFLAGS} "
		MY_CXXFLAGS="${CXXFLAGS} "
	fi
	
	if use amd64; then
		MY_CFLAGS="${MY_CFLAGS}-fPIC"
		MY_CXXFLAGS="${MY_CXXFLAGS}-fPIC"
		BUILD_ARCH="x86_64"
	fi
	
	use valgrind && VALGRIND_STATE=ON
	use openmp && OPENMP_STATE=ON
	use mathlibs && MATHLIBS_STATE=ON
	use profiling && PROFILING_STATE=ON
	use pathopt2 && PATHOPT2_STATE=ON
	use fortran && FORTRAN_STATE=ON
	use debugger && DEBUGGER_STATE=ON
	
	if use native; then
                use fortran && FORTRAN_COMPILER="${COMPILER_PATH}/pathFC"
                C_COMPILER="${COMPILER_PATH}/pathcc"
                CXX_COMPILER="${COMPILER_PATH}/pathCC"
	else
		use fortran && FORTRAN_COMPILER=$(tc-getFC)
		C_COMPILER=$(tc-getCC)
		CXX_COMPILER=$(tc-getCXX)
	fi

	mycmakeargs=(
		-DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
		-DPATH64_ENABLE_TARGETS=${BUILD_ARCH}
		-DPATH64_ENABLE_MATHLIBS=${MATHLIBS_STATE}
		-DPATH64_ENABLE_FORTRAN=${FORTRAN_STATE}
		-DPATH64_ENABLE_VALGRIND=${VALGRIND_STATE}
		-DPATH64_ENABLE_PATHOPT2=${PATHOPT2_STATE}
		-DPATH64_ENABLE_PROFILING=${PROFILING_STATE}
		-DPATH64_ENABLE_PATHDB=${DEBUGGER_STATE}
		-DPSC_CRT_PATH_${BUILD_ARCH}=$(dirname $(gcc -print-file-name=crt1.o) )
		-DPSC_CRTBEGIN_PATH_${BUILD_ARCH}=$(dirname $(gcc -print-libgcc-file-name) )
		-DPSC_DYNAMIC_LINKER_${BUILD_ARCH}=$(gcc --help -v 2>&1 >/dev/null | awk '/-dynamic-linker/ { match($0, "-dynamic-linker +[^ ]+"); print substr($0, RSTART+16, RLENGTH-16) }')
		-DCMAKE_Fortran_COMPILER=${FORTRAN_COMPILER}
		-DCMAKE_C_COMPILER=${C_COMPILER}
		-DCMAKE_C_FLAGS=${MY_CFLAGS}
		-DCMAKE_CXX_COMPILER=${CXX_COMPILER}
		-DCMAKE_CXX_FLAGS=${MY_CXXFLAGS}
	)
	cmake-utils_src_configure
}