ut2004-3186.ebuild

ut2004-3186.ebuild (text/plain), 5.32 KB, created by Adam Mondl (RETIRED) on 2004-03-19 04:42:51 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2

inherit games

DESCRIPTION="Unreal Tournament 2004 - follow-up to the 2003  multi-player first-person shooter"
HOMEPAGE="http://www.unrealtournament2004.com/"

LICENSE="ut2003"
SLOT="0"
KEYWORDS="~x86 ~amd64"
RESTRICT="nostrip"

DEPEND="virtual/glibc"
RDEPEND="opengl? ( virtual/opengl )
	alsa? ( >=media-libs/alsa-lib-1.0.2 )
	dedicated? ( app-misc/screen )"

S=${WORKDIR}

dir=${GAMES_PREFIX_OPT}/${PN}
Ddir=${D}/${dir}

pkg_setup() {
	check_license || die "License check failed"
	ewarn "The installed game takes about X.XGB of space!"
	cdrom_get_cds CD1/System/UT2004.ini
	games_pkg_setup
}

src_install() {
	dodir ${dir}
	dodir ${dir}/System

	# Disk 1
	einfo "Copying files from Disk 1..."
	cp -r ${CDROM_ROOT}/CD1/{Animations,ForceFeedback,Help,KarmaData,Maps,Sounds,Textures,Web} ${Ddir} || die "copying files"
	cp -r ${CDROM_ROOT}/CD1/System/{editorres/*,*.{bat,bmp,dat,det,est,frt,ini,int,itt,kot,md5,smt,tmt,u,upl,url}} ${Ddir}/System || die "copying files"
	mkdir -p ${Ddir}/Manual || dir "creating manual folder"
	cp ${CDROM_ROOT}/CD1/Manual/Manual.pdf ${Ddir}/Manual || die "copying manual"
	mkdir -p ${Ddir}/Benchmark/Stuff || dir "creating benchmark folders"
	cp -r ${CDROM_ROOT}/CD1/Benchmark/Stuff/* ${Ddir}/Benchmark/Stuff || die "copying benchmark files"

	# Disk 2
	einfo "Copying files from Disk 2..."
	cp -r ${CDROM_ROOT}/CD2/{Sounds,Textures} ${Ddir} || die "copying files"

	# Disk 3
	einfo "Copying files from Disk 3..."
	cp -r ${CDROM_ROOT}/CD3/Textures ${Ddir} || die "copying files"

	#Disk 4
	einfo "Copying files from Disk 4..."
	cp -r ${CDROM_ROOT}/CD4/{Music,StaticMeshes,Textures} ${Ddir} || die "copying files"

	#Disk 5
	einfo "Copying files from Disk 5..."
	cp -r ${CDROM_ROOT}/CD5/{Music,Sounds,Speech} ${Ddir} || die "copying files"

	#Disk 6
	einfo "Copying files from Disk 6..."
	cp -r ${CDROM_ROOT}/CD6/{Extras,Sounds,Speech} ${Ddir} || die "copying files"

	# create empty files in Benchmark
	for j in {CSVs,Logs,Results} ; do
		mkdir -p ${Ddir}/Benchmark/${j} || die "creating folders"
		touch ${Ddir}/Benchmark/${j}/DO_NOT_DELETE.ME || die "creating files"
	done

	# unpack_makeself won't take absolute path
	unpack_makeself ${CDROM_ROOT}/linux-installer.sh || die "unpacking linux installer"

	# install extra help files
	insinto ${dir}/Help
	doins ${S}/Unreal.bmp ${S}/UT2004Logo.bmp

	# install eula
	insinto ${dir}
	doins ${S}/UT2004_EULA.txt

	# install System.inis
	insinto ${dir}/System
	doins ${S}/ini-{det,est,frt,int,itt,kot,smt,tmt}.tar

	# copy ut2004
	exeinto ${dir}
	doexe ${S}/bin/ut2004 || die "copying ut2004"

	if [ "`use alsa`" ]; then
		dosym /usr/lib/libSDL-1.2.so.0 ${dir}/System/libSDL-1.2.so.0 || die "SDL symlink"
		dosym /usr/lib/libopenal.so.0 ${dir}/System/openal.so || die "OpenAL symlink"
	fi
	if [ "`use amd64`" ]; then
		# uncompress amd64 files
		tar -xf ${S}/linux-amd64.tar || die "unpacking amd64 files"
		exeinto ${dir}/System
		doexe ${S}/System/{ut2004-bin,ucc-bin} || die "copying ut2004/ucc"
	else
	# uncompress x86 files
		tar -xf ${S}/linux-x86.tar || die "unpacking x86 files"
		exeinto ${dir}/System
		doexe ${S}/System/{ut2004-bin,ucc-bin} || die "copying ut2004/ucc"
	fi

	# uncompressing files
	einfo "Uncompressing files... this may take a while..."
	for j in {Animations,Maps,Sounds,StaticMeshes,Textures} ; do
		games_ut_unpack ${Ddir}/${j} || die "uncompressing files"
	done

	# installing documentation/icon
	dodoc ${S}/README.linux || die "dodoc README.linux"
	insinto /usr/share/pixmaps;
	doins ${S}/ut2004.xpm || die "copying pixmap"
	insinto ${dir}
	doins ${S}/README.linux ${S}/ut2004.xpm || die "copying readme/icon"

	sed -e "s:GENTOO_DIR:${dir}:" ${FILESDIR}/ut2004 > ut2004
	dogamesbin ut2004

	# now, since these files are coming off a cd, the times/sizes/md5sums wont
	# be different ... that means portage will try to unmerge some files (!)
	# we run touch on ${D} so as to make sure portage doesnt do any such thing
	find ${Ddir} -exec touch '{}' \;

	prepgamesdirs
	make_desktop_entry ut2004 "Unreal Tournament 2004" ut2004.xpm
}

pkg_postinst() {
	games_pkg_postinst

	# here is where we check for the existence of a cdkey...
	# if we don't find one, we ask the user for it
	if [ -f ${dir}/System/cdkey ]; then
		einfo "A cdkey file is already present in ${dir}/System"
	else
		ewarn "You MUST run this before playing the game:"
		ewarn "ebuild /var/db/pkg/${CATEGORY}/${PF}/${PF}.ebuild config"
		ewarn "That way you can [re]enter your cdkey."
	fi
	echo
	einfo "To play the game run:"
	einfo " ut2004"
}

pkg_postrm() {
	ewarn "This package leaves a cdkey file in ${dir}/System that you need"
	ewarn "to remove to completely get rid of this game's files."
}

pkg_config() {
	ewarn "Your CD key is NOT checked for validity here."
	ewarn "  Make sure you type it in correctly."
	eerror "If you CTRL+C out of this, the game will not run!"
	echo
	einfo "CD key format is: XXXXX-XXXXX-XXXXX-XXXXX"
	while true ; do
		einfo "Please enter your CD key:"
		read CDKEY1
		einfo "Please re-enter your CD key:"
		read CDKEY2
		if [ "$CDKEY1" == "" ] ; then
			echo "You entered a blank CD key.  Try again."
		else
			if [ "$CDKEY1" == "$CDKEY2" ] ; then
				echo "$CDKEY1" | tr a-z A-Z > ${dir}/System/cdkey
				einfo "Thank you!"
				break
			else
				eerror "Your CD key entries do not match.  Try again."
			fi
		fi
	done
}