Misc fixes.

biew-6.1.0-r1.ebuild (text/plain), 1.06 KB, created by Kevin McCarthy (RETIRED) on 2011-02-04 16:49:06 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
inherit flag-o-matic toolchain-funcs versionator

MY_P=${PN}-$(replace_all_version_separators "")

DESCRIPTION="A portable viewer of binary files, hexadecimal and disassembler modes."
HOMEPAGE="http://beye.sourceforge.net/"
SRC_URI="mirror://sourceforge/beye/${PV}/${MY_P}-src.tar.bz2"
S=${WORKDIR}/${MY_P}

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gpm"

RDEPEND="gpm? ( sys-libs/gpm )"
DEPEND="${RDEPEND}"

src_prepare() {
	sed -i -e 's^man/man1/biew.1^share/man/man1/biew.1^' makefile || die "Failed to edit makefile."
}

src_configure() {
	if use gpm; then
		append-flags -DHAVE_MOUSE
	else
		append-flags -UHAVE_MOUSE
	fi
	./configure --datadir=/usr/share/${PN} \
		--prefix=/usr \
		--cc="$(tc-getCC)" \
		--ld="$(tc-getCC)" \
		--as="$(tc-getAS)" \
		--ranlib="$(tc-getRANLIB)" || die "configure failed."
}

src_compile() {
	emake LDFLAGS="${LDFLAGS}"
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc doc/{biew_en,release,unix}.txt
}