apcupsd-3.8.5.ebuild

apcupsd-3.8.5.ebuild (text/plain), 2.05 KB, created by Chris PeBenito (RETIRED) on 2002-07-24 20:37:02 UTC

# Copyright 1999-2002 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

S=${WORKDIR}/${P}
DESCRIPTION="APC UPS daemon with tcp/ip remote shutdown"
SRC_URI="http://www.sibbald.com/apcupsd/download/${P}.tar.gz
	 ftp://ftp.apcupsd.org/pub/apcupsd/stable/tar/${P}.tar.gz"
HOMEPAGE="http://www.sibbald.com/apcupsd/"
 
DEPEND="virtual/glibc
	nls? ( sys-devel/gettext )
	ncurses? ( >=sys-libs/ncurses-5.2 )"

SLOT="0"
KEYWORDS="x86 ppc"
LICENSE="GPL-2"

src_compile() {
	local myconf

#	There is a config option for tcpd, but it is currently
#	broken, and disabled in configure.  once thats fixed, 
#	a conditional dependency for tcp-wrappers should be added
#	and the this uncommented
#
#	use tcpd && myconf="${myconf} --with-libwrap=/usr"

	use nls && myconf="${myconf} --enable-nls --enable-libintl"
	use ncurses && myconf="${myconf} --enable-powerflute"

	./configure \
			--host=${CHOST} \
			--prefix=/usr \
			--mandir=/usr/share/man \
			--infodir=/usr/share/info \
			--enable-pthreads \
			${myconf} \
			|| die "configure failed"  
	emake || die
}
 
src_install () {
	dosbin apcupsd apcaccess apcnisd apctest
	use ncurses && dosbin powerflute
	cd ${S}/etc
	dodir etc/apcupsd
	insinto etc/apcupsd
	doins *.conf
	exeinto etc/apcupsd
	doexe changeme commfailure commok mainsback onbattery
	doexe ${FILESDIR}/apccontrol
	dodir var/log/apcupsd
	sed -e "s:/etc/apcupsd:/var/log/apcupsd:g" ${D}/etc/apcupsd/apcupsd.conf > ${D}/etc/apcupsd/apcupsd.conf.tmp
	mv ${D}/etc/apcupsd/apcupsd.conf.tmp ${D}/etc/apcupsd/apcupsd.conf   
	cd ${S}/doc
        mv ${S}/doc/apcupsd.man ${S}/doc/apcupsd.8
	doman apcupsd.8
	rm apcupsd.8  
	dodoc *
	dodoc ${FILESDIR}/halt
	docinto developers
	dodoc developers/*
	docinto developers/APC
	dodoc developers/APC/*
	docinto manual
	dohtml manual/*
	dodir /etc/init.d
	exeinto /etc/init.d
	doexe ${FILESDIR}/apcupsd 
}

pkg_postinst() {
	einfo "The /etc/init.d/halt.sh will have to manually be modified to"
	einfo "power off the UPS at the end of a power fail shutdown."
	einfo "See the documentation for details."
}